configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.60)
   5
   6
   7 AC_INIT(paraslash, [git], maan@systemlinux.org)
   8 AC_CONFIG_HEADER([config.h])
   9
  10 AC_PATH_PROG(UNAMEPATH, uname, no)
  11 if test "$UNAMEPATH" = "no"; then
  12         AC_MSG_ERROR(unable to determine system type)
  13 fi
  14 AC_MSG_CHECKING(os type)
  15 OSTYPE="`$UNAMEPATH -s`"
  16 AC_MSG_RESULT("$OSTYPE")
  17
  18 if test "$OSTYPE" = "SunOS"; then
  19         # needed on SunOS for socket magic
  20         arch_cppflags="-D_XOPEN_SOURCE=500 -D__EXTENSIONS__"
  21         AC_SUBST(arch_cppflags)
  22 fi
  23
  24 AC_C_BIGENDIAN()
  25
  26 AC_PROG_CC
  27 AC_PROG_CPP
  28 AC_PROG_INSTALL
  29 AC_REPLACE_FNMATCH
  30
  31 AC_HEADER_DIRENT
  32 AC_HEADER_STDC
  33 AC_HEADER_SYS_WAIT
  34 AC_HEADER_STDBOOL
  35 AC_CHECK_HEADERS([arpa/inet.h ctype.h fcntl.h limits.h netdb.h netinet/in.h \
  36         stdlib.h string.h sys/socket.h sys/time.h sys/timeb.h sys/un.h \
  37         sys/ipc.h unistd.h utime.h stddef.h],
  38         [], [AC_MSG_ERROR([$ac_header not found])])
  39
  40 # Checks for typedefs, structures, and compiler characteristics.
  41 AC_C_CONST
  42 AC_C_INLINE
  43 AC_TYPE_OFF_T
  44 AC_TYPE_PID_T
  45 AC_TYPE_SIZE_T
  46 AC_HEADER_TIME
  47 AC_STRUCT_TM
  48 AC_TYPE_INT8_T
  49 AC_TYPE_INT16_T
  50 AC_TYPE_INT32_T
  51 AC_TYPE_INT64_T
  52 AC_TYPE_MODE_T
  53 AC_TYPE_SSIZE_T
  54 AC_TYPE_UID_T
  55 AC_TYPE_UINT8_T
  56 AC_TYPE_UINT16_T
  57 AC_TYPE_UINT32_T
  58 AC_TYPE_UINT64_T
  59
  60 # Checks for library functions.
  61 AC_FUNC_FORK
  62 AC_PROG_GCC_TRADITIONAL
  63 AC_FUNC_MALLOC
  64 AC_FUNC_MEMCMP
  65 AC_FUNC_MKTIME
  66 AC_FUNC_MMAP
  67 AC_FUNC_REALLOC
  68 AC_FUNC_SELECT_ARGTYPES
  69 AC_TYPE_SIGNAL
  70 AC_FUNC_STAT
  71 AC_FUNC_STRFTIME
  72 AC_FUNC_VPRINTF
  73 AC_FUNC_CLOSEDIR_VOID
  74 AC_FUNC_LSTAT
  75
  76 AC_CHECK_FUNCS([atexit dup2 memchr memmove memset \
  77         regcomp select strchr strdup strerror strstr strtol uname \
  78         fchdir gettimeofday localtime_r munmap strcasecmp strcspn \
  79         strncasecmp strrchr strspn alarm mkdir inet_ntoa socket], [],
  80         [AC_MSG_ERROR([function not found, cannot live without it])])
  81
  82 cmdline_dir="cmdline"
  83 AC_SUBST(cmdline_dir)
  84 AC_DEFUN([add_cmdline],[$(for i in $@; do printf "${i}.cmdline "; done)])
  85
  86
  87 all_errlist_objs="server mp3_afh afh_common vss command net string signal time
  88 daemon stat crypt http_send close_on_fork ipc acl afh fade amp_filter
  89 dccp_send fd user_list chunk_queue afs aft mood score attribute blob ringbuffer
  90 playlist sched audiod grab_client filter_common wav_filter compress_filter
  91 http_recv dccp_recv recv_common write_common file_write audiod_command
  92 client_common recv stdout filter stdin audioc write client exec send_common ggo
  93 udp_recv udp_send color fec fecdec_filter prebuffer_filter mm
  94 server_command_list afs_command_list audiod_command_list bitstream imdct wma_afh
  95 wma_common wmadec_filter buffer_tree
  96 "
  97
  98 executables="recv filter audioc write client afh audiod"
  99
 100 recv_cmdline_objs="add_cmdline(recv http_recv dccp_recv udp_recv)"
 101
 102 recv_errlist_objs="http_recv recv_common recv time string net dccp_recv
 103         fd sched stdout ggo udp_recv fec buffer_tree"
 104 recv_ldflags=""
 105
 106 filter_cmdline_objs="add_cmdline(filter compress_filter amp_filter prebuffer_filter)"
 107 filter_errlist_objs="filter_common wav_filter compress_filter filter string
 108         stdin stdout sched fd amp_filter ggo fecdec_filter fec
 109         prebuffer_filter time bitstream imdct wma_common wmadec_filter buffer_tree"
 110 filter_ldflags="-lm"
 111 filters=" compress wav amp fecdec wmadec prebuffer"
 112
 113 audioc_cmdline_objs="add_cmdline(audioc)"
 114 audioc_errlist_objs="audioc string net fd"
 115 audioc_ldflags=""
 116
 117 audiod_cmdline_objs="add_cmdline(audiod compress_filter http_recv dccp_recv file_write client amp_filter udp_recv prebuffer_filter)"
 118 audiod_errlist_objs="audiod signal string daemon stat net
 119         time grab_client filter_common wav_filter compress_filter amp_filter http_recv dccp_recv
 120         recv_common fd sched write_common file_write audiod_command crypt fecdec_filter
 121         client_common ggo udp_recv color fec prebuffer_filter audiod_command_list
 122         bitstream imdct wma_common wmadec_filter buffer_tree"
 123 audiod_ldflags="-lm"
 124 audiod_audio_formats="wma"
 125
 126 afh_cmdline_objs="add_cmdline(afh)"
 127 afh_errlist_objs="afh string fd mp3_afh afh_common time wma_afh wma_common"
 128 afh_ldflags=""
 129
 130 server_cmdline_objs="add_cmdline(server)"
 131 server_errlist_objs="server afh_common mp3_afh vss command net string signal
 132         time daemon crypt http_send close_on_fork mm
 133         ipc dccp_send fd user_list chunk_queue afs aft mood score attribute
 134         blob playlist sched acl send_common udp_send color fec
 135         server_command_list afs_command_list wma_afh wma_common"
 136 server_ldflags=""
 137 server_audio_formats="mp3 wma"
 138
 139 write_cmdline_objs="add_cmdline(write file_write)"
 140 write_errlist_objs="write write_common file_write time fd string sched stdin
 141         buffer_tree ggo"
 142 write_ldflags=""
 143 writers=" file"
 144 default_writer="FILE_WRITE"
 145
 146 client_cmdline_objs="add_cmdline(client)"
 147 client_errlist_objs="client net string crypt fd sched stdin stdout time
 148         client_common buffer_tree"
 149 client_ldflags=""
 150
 151 gui_cmdline_objs="add_cmdline(gui)"
 152 gui_errlist_objs="exec signal string stat ringbuffer fd"
 153 gui_other_objs="gui gui_theme"
 154 gui_objs="$gui_cmdline_objs $gui_errlist_objs $gui_other_objs"
 155
 156 fade_cmdline_objs="add_cmdline(fade)"
 157 fade_errlist_objs="fade exec string fd"
 158
 159
 160 ########################################################################### snprintf
 161 # ===========================================================================
 162 #        http://www.nongnu.org/autoconf-archive/ax_func_snprintf.html
 163 # ===========================================================================
 164 #
 165 # SYNOPSIS
 166 #
 167 #   AX_FUNC_SNPRINTF
 168 #
 169 # DESCRIPTION
 170 #
 171 #   Checks for a fully C99 compliant snprintf, in particular checks whether
 172 #   it does bounds checking and returns the correct string length; does the
 173 #   same check for vsnprintf. If no working snprintf or vsnprintf is found,
 174 #   it prints an error message and aborts.
 175 #
 176 # LICENSE
 177 #
 178 #   Copyright (c) 2008 Ruediger Kuhlmann <info@ruediger-kuhlmann.de>
 179 #
 180 #   Copying and distribution of this file, with or without modification, are
 181 #   permitted in any medium without royalty provided the copyright notice
 182 #   and this notice are preserved.
 183
 184 AU_ALIAS([AC_FUNC_SNPRINTF], [AX_FUNC_SNPRINTF])
 185 AC_DEFUN([AX_FUNC_SNPRINTF],
 186 [AC_CHECK_FUNCS(snprintf vsnprintf)
 187 AC_MSG_CHECKING(for working snprintf)
 188 AC_CACHE_VAL(ac_cv_have_working_snprintf,
 189 [AC_TRY_RUN(
 190 [#include <stdio.h>
 191
 192 int main(void)
 193 {
 194     char bufs[5] = { 'x', 'x', 'x', '\0', '\0' };
 195     char bufd[5] = { 'x', 'x', 'x', '\0', '\0' };
 196     int i;
 197     i = snprintf (bufs, 2, "%s", "111");
 198     if (strcmp (bufs, "1")) exit (1);
 199     if (i != 3) exit (1);
 200     i = snprintf (bufd, 2, "%d", 111);
 201     if (strcmp (bufd, "1")) exit (1);
 202     if (i != 3) exit (1);
 203     exit(0);
 204 }], ac_cv_have_working_snprintf=yes, ac_cv_have_working_snprintf=no, ac_cv_have_working_snprintf=cross)])
 205 AC_MSG_RESULT([$ac_cv_have_working_snprintf])
 206 AC_MSG_CHECKING(for working vsnprintf)
 207 AC_CACHE_VAL(ac_cv_have_working_vsnprintf,
 208 [AC_TRY_RUN(
 209 [#include <stdio.h>
 210 #include <stdarg.h>
 211
 212 int my_vsnprintf (char *buf, const char *tmpl, ...)
 213 {
 214     int i;
 215     va_list args;
 216     va_start (args, tmpl);
 217     i = vsnprintf (buf, 2, tmpl, args);
 218     va_end (args);
 219     return i;
 220 }
 221
 222 int main(void)
 223 {
 224     char bufs[5] = { 'x', 'x', 'x', '\0', '\0' };
 225     char bufd[5] = { 'x', 'x', 'x', '\0', '\0' };
 226     int i;
 227     i = my_vsnprintf (bufs, "%s", "111");
 228     if (strcmp (bufs, "1")) exit (1);
 229     if (i != 3) exit (1);
 230     i = my_vsnprintf (bufd, "%d", 111);
 231     if (strcmp (bufd, "1")) exit (1);
 232     if (i != 3) exit (1);
 233     exit(0);
 234 }], ac_cv_have_working_vsnprintf=yes, ac_cv_have_working_vsnprintf=no, ac_cv_have_working_vsnprintf=cross)])
 235 AC_MSG_RESULT([$ac_cv_have_working_vsnprintf])
 236 if test x$ac_cv_have_working_snprintf$ac_cv_have_working_vsnprintf != "xyesyes"; then
 237 AC_MSG_ERROR([fatal: buggy snprintf() detected])
 238 fi])
 239 AX_FUNC_SNPRINTF()
 240 ########################################################################### osl
 241 have_osl=yes
 242 OLD_CPPFLAGS="$CPPFLAGS"
 243 OLD_LD_FLAGS="$LDFLAGS"
 244 OLD_LIBS="$LIBS"
 245 AC_ARG_WITH(osl_headers, [AC_HELP_STRING(--with-osl-headers=dir,
 246         [look for osl.h also in dir])])
 247 if test -n "$with_osl_headers"; then
 248         osl_cppflags="-I$with_osl_headers"
 249         CPPFLAGS="$CPPFLAGS $osl_cppflags"
 250 fi
 251 AC_ARG_WITH(osl_libs, [AC_HELP_STRING(--with-osl-libs=dir,
 252         [look for libosl also in dir])])
 253 if test -n "$with_osl_libs"; then
 254         osl_libs="-L$with_osl_libs"
 255         LDFLAGS="$LDFLAGS $osl_libs"
 256 fi
 257
 258 AC_CHECK_HEADER(osl.h, [], have_osl=no)
 259 AC_CHECK_LIB([osl], [osl_open_table], [], have_osl=no)
 260 if test "$have_osl" = "no"; then
 261         AC_MSG_WARN([libosl not found, can not build para_server.
 262 Download libosl at
 263         http://systemlinux.org/~maan/osl
 264 or execute
 265         git clone git://git.tuebingen.mpg.de/osl
 266         ])
 267 else
 268         extras="$extras server"
 269         executables="$executables server"
 270         AC_SUBST(osl_cppflags)
 271         server_ldflags="$server_ldflags $osl_libs -losl"
 272 fi
 273 CPPFLAGS="$OLD_CPPFLAGS"
 274 LDFLAGS="$OLD_LDFLAGS"
 275 LIBS="$OLD_LIBS"
 276 ###################################################################### openssl
 277 OLD_CPPFLAGS="$CPPFLAGS"
 278 OLD_LD_FLAGS="$LDFLAGS"
 279 OLD_LIBS="$LIBS"
 280 have_openssl="yes"
 281 AC_ARG_WITH(openssl_headers, [AC_HELP_STRING(--with-openssl-headers=dir,
 282         [look for openssl headers also in dir])])
 283 if test -n "$with_openssl_headers"; then
 284         openssl_cppflags="-I$with_openssl_headers"
 285         CPPFLAGS="$CPPFLAGS $openssl_cppflags"
 286 fi
 287 AC_ARG_WITH(openssl_libs, [AC_HELP_STRING(--with-openssl-libs=dir,
 288         [look for openssl libraries also in dir])])
 289 if test -n "$with_openssl_libs"; then
 290         openssl_libs="-L$with_openssl_libs"
 291         LDFLAGS="$LDFLAGS $openssl_libs"
 292 fi
 293 AC_CHECK_HEADER(openssl/ssl.h, [], [have_openssl="no"])
 294 AC_CHECK_LIB([crypto], [RAND_bytes], [], [have_openssl="no"])
 295 if test "$have_openssl" = "no" -a -z "$with_openssl_headers$with_openssl_libs"; then
 296         # try harder: openssl is sometimes installed in /usr/local/ssl
 297         openssl_cppflags="-I/usr/local/ssl/include"
 298         CPPFLAGS="$CPPFLAGS $openssl_cppflags"
 299         openssl_libs="-L/usr/local/ssl/lib"
 300         LDFLAGS="$LDFLAGS $openssl_libs"
 301         # clear cache
 302         unset ac_cv_header_openssl_ssl_h 2> /dev/null
 303         unset ac_cv_lib_crypto_RAND_bytes 2> /dev/null
 304         AC_CHECK_HEADER(openssl/ssl.h, [have_openssl="yes"], [])
 305         if test "$have_openssl" = "yes"; then
 306                 AC_CHECK_LIB([crypto], [RAND_bytes], [], [have_openssl="no"])
 307         fi
 308 fi
 309 if test "$have_openssl" = "yes"; then
 310         AC_DEFINE(HAVE_OPENSSL, 1, [define to 1 to turn on openssl support])
 311         AC_SUBST(openssl_cppflags)
 312         openssl_libs="$openssl_libs -lssl -lcrypto"
 313         server_ldflags="$server_ldflags $openssl_libs"
 314         client_ldflags="$client_ldflags $openssl_libs"
 315         audiod_ldflags="$audiod_ldflags $openssl_libs"
 316 else
 317         AC_MSG_ERROR([openssl libraries not found])
 318 fi
 319 CPPFLAGS="$OLD_CPPFLAGS"
 320 LDFLAGS="$OLD_LDFLAGS"
 321 LIBS="$OLD_LIBS"
 322 ########################################################################### libsocket
 323 AC_CHECK_LIB([c], [socket],
 324         [socket_lib=],
 325         [socket_lib="-lsocket"]
 326 )
 327 server_ldflags="$server_ldflags $socket_lib"
 328 client_ldflags="$client_ldflags $socket_lib"
 329 audioc_ldflags="$audioc_ldflags $socket_lib"
 330 audiod_ldflags="$audiod_ldflags $socket_lib"
 331 recv_ldflags="$recv_ldflags $socket_lib"
 332 AC_SEARCH_LIBS([connect],[socket],[],[
 333         AC_MSG_ERROR([Fatal: Did not find connect().])
 334 ],[])
 335 ########################################################################### libnsl
 336 AC_CHECK_LIB([c], [gethostbyname],
 337         [nsl_lib=],
 338         [nsl_lib="-lnsl"]
 339 )
 340 server_ldflags="$server_ldflags $nsl_lib"
 341 client_ldflags="$client_ldflags $nsl_lib"
 342 audioc_ldflags="$audioc_ldflags $nsl_lib"
 343 recv_ldflags="$recv_ldflags $nsl_lib"
 344 AC_SEARCH_LIBS([inet_ntoa],[nsl],[],[
 345         AC_MSG_ERROR([Fatal: Did not find inet_ntoa().])
 346 ],[])
 347 ########################################################################### ucred
 348 AC_MSG_CHECKING(for struct ucred)
 349 AC_TRY_LINK([
 350         #define _GNU_SOURCE
 351         #include <sys/types.h>
 352         #include <sys/socket.h>
 353 ],[
 354         struct ucred sucred; sucred.pid=0;
 355 ],[have_ucred=yes],[have_ucred=no])
 356 AC_MSG_RESULT($have_ucred)
 357 if test ${have_ucred} = yes; then
 358         AC_DEFINE(HAVE_UCRED, 1, define to 1 you have struct ucred)
 359 fi
 360
 361 ########################################################################### curses
 362 have_curses="yes"
 363 OLD_CPPFLAGS="$CPPFLAGS"
 364 OLD_LD_FLAGS="$LDFLAGS"
 365 OLD_LIBS="$LIBS"
 366 AC_ARG_WITH(curses_headers, [AC_HELP_STRING(--with-curses-headers=dir,
 367         [look for curses.h also in dir])])
 368 if test -n "$with_curses_headers"; then
 369         curses_cppflags="-I$with_curses_headers"
 370         CPPFLAGS="$CPPFLAGS $curses_cppflags"
 371 fi
 372 AC_ARG_WITH(curses_libs, [AC_HELP_STRING(--with-curses-libs=dir,
 373         [look for libcurses also in dir])])
 374 if test -n "$with_curses_libs"; then
 375         curses_libs="-L$with_curses_libs"
 376         LDFLAGS="$LDFLAGS $curses_libs"
 377 fi
 378 AC_CHECK_HEADER(curses.h, [], [
 379         have_curses="no"
 380 ])
 381 AC_CHECK_LIB([curses], [initscr], [], [
 382         have_curses="no"
 383 ])
 384 if test "$have_curses" = "yes"; then
 385         AC_SUBST(curses_cppflags)
 386         AC_DEFINE(HAVE_NCURSES, 1, [define to 1 to turn on curses support])
 387         extras="$extras gui"
 388         executables="$executables gui"
 389 else
 390         AC_MSG_WARN([cannot build para_gui])
 391 fi
 392 CPPFLAGS="$OLD_CPPFLAGS"
 393 LDFLAGS="$OLD_LDFLAGS"
 394 LIBS="$OLD_LIBS"
 395
 396 ########################################################################### ip_mreqn
 397 AC_MSG_CHECKING(for struct ip_mreqn (UDPv4 multicast))
 398 AC_TRY_LINK([
 399         #include <netdb.h>
 400         #include <net/if.h>
 401 ],[
 402         struct ip_mreqn mn;
 403         mn.imr_ifindex = 0;
 404 ],[have_ip_mreqn=yes],[have_ip_mreqn=no])
 405 AC_MSG_RESULT($have_ip_mreqn)
 406 if test ${have_ip_mreqn} = yes; then
 407         AC_DEFINE(HAVE_IP_MREQN, 1, define to 1 you have struct ip_mreqn)
 408 fi
 409 ########################################################################### osx
 410
 411 AC_MSG_CHECKING(for CoreAudio (MacOs))
 412 AC_TRY_LINK([
 413         #include <CoreAudio/CoreAudio.h>
 414 ],[
 415         AudioDeviceID id;
 416 ],[have_core_audio=yes],[have_core_audio=no])
 417 AC_MSG_RESULT($have_core_audio)
 418 if test ${have_core_audio} = yes; then
 419         f1="-framework CoreAudio"
 420         f2="-framework AudioToolbox"
 421         f3="-framework AudioUnit"
 422         f4="-framework CoreServices"
 423         f="$f1 $f2 $f3 $f4"
 424
 425         all_errlist_objs="$all_errlist_objs osx_write"
 426         audiod_errlist_objs="$audiod_errlist_objs osx_write"
 427         audiod_cmdline_objs="$audiod_cmdline_objs osx_write.cmdline"
 428         audiod_ldflags="$audiod_ldflags $f"
 429
 430         write_errlist_objs="$write_errlist_objs osx_write"
 431         write_cmdline_objs="$write_cmdline_objs osx_write.cmdline"
 432         write_ldflags="$write_ldflags $f"
 433         writers="$writers osx"
 434         default_writer="OSX_WRITE"
 435         AC_DEFINE(HAVE_CORE_AUDIO, 1, define to 1 on Mac Os X)
 436 fi
 437 ########################################################### ogg/vorbis/speex
 438 have_ogg="yes"
 439 OLD_CPPFLAGS="$CPPFLAGS"
 440 OLD_LD_FLAGS="$LDFLAGS"
 441 OLD_LIBS="$LIBS"
 442 AC_ARG_WITH(ogg_headers, [AC_HELP_STRING(--with-ogg-headers=dir,
 443         [look for ogg headers also in dir])])
 444 AC_ARG_WITH(ogg_libs, [AC_HELP_STRING(--with-ogg-libs=dir,
 445         [look for ogg libs also in dir])])
 446 AC_ARG_WITH(vorbis_headers, [AC_HELP_STRING(--with-vorbis-headers=dir,
 447         [look for vorbis headers also in dir])])
 448 AC_ARG_WITH(vorbis_libs, [AC_HELP_STRING(--with-vorbis-libs=dir,
 449         [look for vorbis libs also in dir])])
 450 AC_ARG_WITH(speex_headers, [AC_HELP_STRING(--with-speex-headers=dir,
 451         [look for speex headers also in dir])])
 452 AC_ARG_WITH(speex_libs, [AC_HELP_STRING(--with-speex-libs=dir,
 453         [look for speex libs also in dir])])
 454
 455 if test -n "$with_ogg_headers"; then
 456         ogg_cppflags="-I$with_ogg_headers"
 457         CPPFLAGS="$CPPFLAGS $ogg_cppflags"
 458 fi
 459 if test -n "$with_ogg_libs"; then
 460         ogg_libs="-L$with_ogg_libs"
 461         LDFLAGS="$LDFLAGS $ogg_libs"
 462 fi
 463 AC_CHECK_HEADERS([ogg/ogg.h], [], [ have_ogg="no"; ])
 464 AC_CHECK_LIB([ogg], [ogg_stream_init], [], [ have_ogg="no" ])
 465
 466 have_vorbis="yes"
 467 have_speex="yes"
 468 if test "$have_ogg" = "yes"; then
 469         # vorbis
 470         if test -n "$with_vorbis_headers"; then
 471                 vorbis_cppflags="-I$with_vorbis_headers"
 472                 CPPFLAGS="$CPPFLAGS $vorbis_cppflags"
 473         fi
 474         if test -n "$with_vorbis_libs"; then
 475                 vorbis_libs="-L$with_vorbis_libs"
 476                 LDFLAGS="$LDFLAGS $vorbis_libs"
 477         fi
 478         AC_CHECK_HEADERS([vorbis/codec.h], [], [ have_vorbis="no" ])
 479         AC_CHECK_LIB([vorbis], [vorbis_info_init], [], [ have_vorbis="no" ])
 480
 481         # speex
 482         if test -n "$with_speex_headers"; then
 483                 speex_cppflags="-I$with_speex_headers"
 484                 CPPFLAGS="$CPPFLAGS $speex_cppflags"
 485         fi
 486         if test -n "$with_speex_libs"; then
 487                 speex_libs="-L$with_speex_libs"
 488                 LDFLAGS="$LDFLAGS $speex_libs"
 489         fi
 490         AC_CHECK_LIB([speex], [speex_decoder_init], [], [ have_speex="no" ])
 491         AC_CHECK_HEADERS([speex/speex.h], [], [ have_speex="no" ])
 492 else
 493         have_vorbis="no"
 494         have_speex="no"
 495 fi
 496
 497 msg="support in para_server/para_filter/para_afh"
 498 if test "$have_vorbis" = "yes" || test "$have_speex" = "yes"; then
 499         AC_SUBST(ogg_cppflags)
 500         ogg_libs="$ogg_libs -logg"
 501         if test "$OSTYPE" = "Darwin"; then
 502                 ogg_libs="-Wl,-bind_at_load $ogg_libs"
 503         fi
 504         server_ldflags="$server_ldflags $ogg_libs"
 505         filter_ldflags="$filter_ldflags $ogg_libs"
 506         audiod_ldflags="$audiod_ldflags $ogg_libs"
 507         afh_ldflags="$afh_ldflags $ogg_libs"
 508         all_errlist_objs="$all_errlist_objs ogg_afh_common"
 509         afh_errlist_objs="$afh_errlist_objs ogg_afh_common"
 510         server_errlist_objs="$server_errlist_objs ogg_afh_common"
 511 else
 512         AC_MSG_WARN([vorbis/speex require ogg])
 513 fi
 514 if test "$have_vorbis" = "yes"; then
 515         all_errlist_objs="$all_errlist_objs oggdec_filter ogg_afh"
 516         AC_DEFINE(HAVE_OGGVORBIS, 1, define to 1 to turn on ogg/vorbis support)
 517         filters="$filters oggdec"
 518         vorbis_libs="-lvorbis -lvorbisfile"
 519         server_ldflags="$server_ldflags $vorbis_libs"
 520         filter_ldflags="$filter_ldflags $vorbis_libs"
 521         audiod_ldflags="$audiod_ldflags $vorbis_libs"
 522         afh_ldflags="$afh_ldflags $vorbis_libs"
 523
 524         server_errlist_objs="$server_errlist_objs ogg_afh"
 525         filter_errlist_objs="$filter_errlist_objs oggdec_filter"
 526         audiod_errlist_objs="$audiod_errlist_objs oggdec_filter"
 527         afh_errlist_objs="$afh_errlist_objs ogg_afh"
 528
 529         audiod_audio_formats="$audiod_audio_formats ogg"
 530         server_audio_formats="$server_audio_formats ogg"
 531 else
 532         AC_MSG_WARN([no ogg/vorbis $msg])
 533 fi
 534 if test "$have_speex" = "yes"; then
 535         all_errlist_objs="$all_errlist_objs spxdec_filter spx_afh spx_common"
 536         AC_DEFINE(HAVE_SPEEX, 1, define to 1 to turn on ogg/speex support)
 537         filters="$filters spxdec"
 538         speex_libs="-lspeex"
 539         server_ldflags="$server_ldflags $speex_libs"
 540         filter_ldflags="$filter_ldflags $speex_libs"
 541         audiod_ldflags="$audiod_ldflags $speex_libs"
 542         afh_ldflags="$afh_ldflags $speex_libs"
 543
 544         server_errlist_objs="$server_errlist_objs spx_afh spx_common"
 545         filter_errlist_objs="$filter_errlist_objs spxdec_filter spx_common"
 546         audiod_errlist_objs="$audiod_errlist_objs spxdec_filter spx_common"
 547         afh_errlist_objs="$afh_errlist_objs spx_afh spx_common"
 548
 549         audiod_audio_formats="$audiod_audio_formats spx"
 550         server_audio_formats="$server_audio_formats spx"
 551 else
 552         AC_MSG_WARN([no ogg/speex $msg])
 553 fi
 554 CPPFLAGS="$OLD_CPPFLAGS"
 555 LDFLAGS="$OLD_LDFLAGS"
 556 LIBS="$OLD_LIBS"
 557 ########################################################################### faad
 558 have_faad=yes
 559 OLD_CPPFLAGS="$CPPFLAGS"
 560 OLD_LD_FLAGS="$LDFLAGS"
 561 OLD_LIBS="$LIBS"
 562 AC_ARG_WITH(faad_headers, [AC_HELP_STRING(--with-faad-headers=dir,
 563         [look for neaacdec.h also in dir])])
 564 if test -n "$with_faad_headers"; then
 565         faad_cppflags="-I$with_faad_headers"
 566         CPPFLAGS="$CPPFLAGS $faad_cppflags"
 567 fi
 568 AC_ARG_WITH(faad_libs, [AC_HELP_STRING(--with-faad-libs=dir,
 569         [look for libfaad also in dir])])
 570 if test -n "$with_faad_libs"; then
 571         faad_libs="-L$with_faad_libs"
 572         LDFLAGS="$LDFLAGS $faad_libs"
 573 fi
 574 AC_CHECK_HEADER(neaacdec.h, [], have_faad=no)
 575 AC_CHECK_LIB([faad], [NeAACDecOpen], [], have_faad=no)
 576 if test "$have_faad" = "yes"; then
 577         AC_DEFINE(HAVE_FAAD, 1, define to 1 if you want to build the aacdec filter)
 578         all_errlist_objs="$all_errlist_objs aac_common aacdec_filter aac_afh"
 579         filter_errlist_objs="$filter_errlist_objs aacdec_filter aac_common"
 580         afh_errlist_objs="$afh_errlist_objs aac_common aac_afh"
 581         audiod_errlist_objs="$audiod_errlist_objs aacdec_filter aac_common"
 582         server_errlist_objs="$server_errlist_objs aac_afh aac_common"
 583         server_ldflags="$server_ldflags $faad_libs -lfaad"
 584         filter_ldflags="$filter_ldflags $faad_libs -lfaad"
 585         audiod_ldflags="$audiod_ldflags $faad_libs -lfaad"
 586         afh_ldflags="$afh_ldflags $faad_libs -lfaad"
 587         audiod_audio_formats="$audiod_audio_formats aac"
 588         server_audio_formats="$server_audio_formats aac"
 589         filters="$filters aacdec"
 590         AC_SUBST(faad_cppflags)
 591 else
 592         AC_MSG_WARN([no aac support in para_audiod/para_filter])
 593 fi
 594 CPPFLAGS="$OLD_CPPFLAGS"
 595 LDFLAGS="$OLD_LDFLAGS"
 596 LIBS="$OLD_LIBS"
 597 ########################################################################### mad
 598 have_mad="yes"
 599 OLD_CPPFLAGS="$CPPFLAGS"
 600 OLD_LD_FLAGS="$LDFLAGS"
 601 OLD_LIBS="$LIBS"
 602
 603 AC_ARG_WITH(mad_headers, [AC_HELP_STRING(--with-mad-headers=dir,
 604         [look for mad.h also in dir])])
 605 if test -n "$with_mad_headers"; then
 606         mad_cppflags="-I$with_mad_headers"
 607         CPPFLAGS="$CPPFLAGS $mad_cppflags"
 608 fi
 609 AC_ARG_WITH(mad_libs, [AC_HELP_STRING(--with-mad-libs=dir,
 610         [look for libmad also in dir])])
 611 if test -n "$with_mad_libs"; then
 612         mad_libs="-L$with_mad_libs"
 613         LDFLAGS="$LDFLAGS $mad_libs"
 614 fi
 615 AC_CHECK_HEADERS([mad.h], [], [
 616         have_mad="no"
 617 ])
 618 AC_CHECK_LIB([mad], [mad_stream_init], [], [
 619         have_mad="no"
 620 ])
 621 if test "$have_mad" = "yes"; then
 622         AC_DEFINE(HAVE_MAD, 1, define to 1 if you want to build the mp3dec filter)
 623         filter_cmdline_objs="$filter_cmdline_objs add_cmdline(mp3dec_filter)"
 624         audiod_cmdline_objs="$audiod_cmdline_objs add_cmdline(mp3dec_filter)"
 625         all_errlist_objs="$all_errlist_objs mp3dec_filter"
 626         filter_errlist_objs="$filter_errlist_objs mp3dec_filter"
 627         audiod_errlist_objs="$audiod_errlist_objs mp3dec_filter"
 628         filter_ldflags="$filter_ldflags $mad_libs -lmad"
 629         audiod_ldflags="$audiod_ldflags $mad_libs -lmad"
 630         audiod_audio_formats="$audiod_audio_formats mp3"
 631         filters="$filters mp3dec"
 632         AC_SUBST(mad_cppflags)
 633 else
 634         AC_MSG_WARN([no mp3dec support in para_audiod/para_filter])
 635 fi
 636 CPPFLAGS="$OLD_CPPFLAGS"
 637 LDFLAGS="$OLD_LDFLAGS"
 638 LIBS="$OLD_LIBS"
 639 ###################################################################### libid3tag
 640 AC_MSG_CHECKING(for libid3tag)
 641 AC_TRY_LINK([
 642         #include <id3tag.h>
 643 ],[
 644         struct id3_tag t = {.flags = 0};
 645 ],[have_libid3tag=yes],[have_libid3tag=no])
 646 AC_MSG_RESULT($have_libid3tag)
 647 if test ${have_libid3tag} = yes; then
 648         AC_DEFINE(HAVE_LIBID3TAG, 1, define to 1 you have libid3tag)
 649         server_ldflags="$server_ldflags -lid3tag"
 650         afh_ldflags="$afh_ldflags -lid3tag"
 651 else
 652         AC_MSG_WARN([no support for id3v2 tags])
 653 fi
 654 ########################################################################### oss
 655 OLD_CPPFLAGS="$CPPFLAGS"
 656 OLD_LD_FLAGS="$LDFLAGS"
 657 OLD_LIBS="$LIBS"
 658
 659 have_oss="yes"
 660 msg="=> will not build para_fade/oss writer"
 661
 662 AC_CHECK_HEADER(sys/soundcard.h, [
 663         extras="$extras fade"
 664         executables="$executables fade"
 665         all_errlist_objs="$all_errlist_objs oss_write"
 666         audiod_errlist_objs="$audiod_errlist_objs oss_write"
 667         audiod_cmdline_objs="$audiod_cmdline_objs add_cmdline(oss_write)"
 668
 669         write_errlist_objs="$write_errlist_objs oss_write"
 670         write_cmdline_objs="$write_cmdline_objs add_cmdline(oss_write)"
 671         writers="$writers oss"
 672         default_writer="OSS_WRITE"
 673         AC_CHECK_LIB(ossaudio, _oss_ioctl, [
 674                         audiod_ldflags="$audiod_ldflags -lossaudio"
 675                         write_ldflags="$write_ldflags -lossaudio"
 676                         fade_ldflags="$write_ldflags -lossaudio"
 677                 ]
 678         )
 679         ],
 680         [
 681                 have_oss="no"
 682                 AC_MSG_WARN([no sys/soundcard.h $msg])
 683         ]
 684 )
 685 CPPFLAGS="$OLD_CPPFLAGS"
 686 LDFLAGS="$OLD_LDFLAGS"
 687 LIBS="$OLD_LIBS"
 688
 689 ########################################################################### alsa
 690 OLD_CPPFLAGS="$CPPFLAGS"
 691 OLD_LD_FLAGS="$LDFLAGS"
 692 OLD_LIBS="$LIBS"
 693
 694 msg="=> no alsa support for para_audiod/para_write"
 695 if test "$OSTYPE" != "Linux"; then
 696         have_alsa="no"
 697 else
 698         have_alsa="yes"
 699 fi
 700 if test "$have_alsa" = "yes"; then
 701         AC_CHECK_HEADERS([alsa/asoundlib.h], [], [
 702                 have_alsa="no"
 703                 AC_MSG_WARN([no alsa/asoundlib $msg])
 704         ])
 705 fi
 706
 707 if test "$have_alsa" = "yes"; then
 708         AC_CHECK_LIB([asound], [snd_pcm_open], [], [
 709                 have_alsa="no"
 710                 AC_MSG_WARN([no libasound $msg])
 711         ])
 712 fi
 713
 714 if test "$have_alsa" = "yes"; then
 715         all_errlist_objs="$all_errlist_objs alsa_write"
 716         audiod_errlist_objs="$audiod_errlist_objs alsa_write"
 717         audiod_cmdline_objs="$audiod_cmdline_objs add_cmdline(alsa_write)"
 718         audiod_ldflags="$audiod_ldflags -lasound"
 719
 720         write_errlist_objs="$write_errlist_objs alsa_write"
 721         write_cmdline_objs="$write_cmdline_objs add_cmdline(alsa_write)"
 722         write_ldflags="$write_ldflags -lasound"
 723         writers="$writers alsa"
 724         default_writer="ALSA_WRITE"
 725 fi
 726
 727 CPPFLAGS="$OLD_CPPFLAGS"
 728 LDFLAGS="$OLD_LDFLAGS"
 729 LIBS="$OLD_LIBS"
 730 ########################################################################### libao
 731 OLD_CPPFLAGS="$CPPFLAGS"
 732 OLD_LD_FLAGS="$LDFLAGS"
 733 OLD_LIBS="$LIBS"
 734
 735 have_ao="yes"
 736 AC_ARG_WITH(ao_headers, [AC_HELP_STRING(--with-ao-headers=dir,
 737         [look for ao/ao.h also in dir])])
 738 if test -n "$with_ao_headers"; then
 739         ao_cppflags="-I$with_ao_headers"
 740         CPPFLAGS="$CPPFLAGS $ao_cppflags"
 741 fi
 742 AC_ARG_WITH(ao_libs, [AC_HELP_STRING(--with-ao-libs=dir,
 743         [look for libao also in dir])])
 744 if test -n "$with_ao_libs"; then
 745         ao_libs="-L$with_ao_libs"
 746         LDFLAGS="$LDFLAGS $ao_libs"
 747 fi
 748 msg="no libao support for para_audiod/para_write"
 749 AC_CHECK_HEADERS([ao/ao.h], [
 750         ], [
 751         have_ao="no"
 752         AC_MSG_WARN([ao.h not found, $msg])
 753 ])
 754 if test "$have_ao" = "yes"; then
 755         AC_CHECK_LIB([ao], [ao_initialize], [], [
 756                 have_ao="no"
 757                 AC_MSG_WARN([ao lib not found or not working, $msg])
 758         ])
 759 fi
 760 if test "$have_ao" = "yes"; then
 761         AC_CHECK_HEADERS([pthread.h], [
 762                 ], [
 763                 have_ao="no"
 764                 AC_MSG_WARN([pthread.h not found, $msg])
 765         ])
 766 fi
 767 if test "$have_ao" = "yes"; then
 768         AC_CHECK_LIB([pthread], [pthread_create], [], [
 769                 have_ao="no"
 770                 AC_MSG_WARN([pthread lib not found or not working, $msg])
 771         ])
 772 fi
 773 if test "$have_ao" = "yes"; then
 774         all_errlist_objs="$all_errlist_objs ao_write"
 775         audiod_errlist_objs="$audiod_errlist_objs ao_write"
 776         audiod_cmdline_objs="$audiod_cmdline_objs add_cmdline(ao_write)"
 777         audiod_ldflags="$audiod_ldflags -lao -lpthread"
 778
 779         write_errlist_objs="$write_errlist_objs ao_write"
 780         write_cmdline_objs="$write_cmdline_objs add_cmdline(ao_write)"
 781         write_ldflags="$write_ldflags $ao_libs -lao -lpthread"
 782         writers="$writers ao"
 783         AC_SUBST(ao_cppflags)
 784 fi
 785
 786 CPPFLAGS="$OLD_CPPFLAGS"
 787 LDFLAGS="$OLD_LDFLAGS"
 788 LIBS="$OLD_LIBS"
 789
 790
 791
 792 AC_SUBST(install_sh, [$INSTALL])
 793 AC_CONFIG_FILES([Makefile])
 794
 795
 796 AC_DEFUN([add_dot_o],[$(for i in $@; do printf "$i.o "; done)])
 797 AC_DEFUN([add_para],[$(for i in $@; do printf "para_$i "; done)])
 798 AC_DEFUN([objlist_to_errlist],[$(for i in $@; do printf "DEFINE_ERRLIST($(echo $i| tr 'a-z' 'A-Z'));"; done) [const char **para_errlist[[]]] = {$(for i in $@; do printf "PARA_ERRLIST($(echo $i | tr 'a-z' 'A-Z')), "; done) }])
 799 ############################################################# error2.h
 800 AC_MSG_NOTICE(creating error2.h)
 801 for i in $executables; do
 802         echo "$i: "
 803         eval echo \$${i}_errlist_objs
 804 done | ./error2.pl > error2.h
 805 for obj in $all_errlist_objs; do
 806         SS="$SS SS_$(echo $obj | tr 'a-z' 'A-Z'),"
 807 done
 808 AC_DEFINE_UNQUOTED(DEFINE_ERRLIST_OBJECT_ENUM,
 809         [enum {$SS NUM_SS}],
 810         [list of all objects that use paraslash's error facility]
 811 )
 812
 813 ################################################################## status items
 814
 815 status_items="basename status num_played mtime bitrate frequency file_size
 816 status_flags format score techinfo afs_mode
 817 attributes_txt decoder_flags audiod_status play_time attributes_bitmap
 818 offset seconds_total stream_start current_time audiod_uptime image_id
 819 lyrics_id duration directory lyrics_name image_name path hash channels
 820 last_played num_chunks chunk_time amplification artist title year album
 821 comment"
 822
 823 result=
 824 for i in $status_items; do
 825         result="$result SI_$(echo $i | tr 'a-z' 'A-Z'), "
 826 done
 827 AC_DEFINE_UNQUOTED(STATUS_ITEM_ENUM, [$result],
 828         [enum of all status items])
 829
 830 result=
 831 for i in $status_items; do
 832         result="$result \"$i\", "
 833 done
 834 AC_DEFINE_UNQUOTED(STATUS_ITEM_ARRAY, [$result],
 835         [char * array of all status items])
 836
 837 AC_DEFINE_UNQUOTED(SERVER_AUDIO_FORMATS, "$server_audio_formats",
 838         [formats supported by para_server and para_afh])
 839
 840 AC_SUBST(executables, add_para($executables))
 841
 842 recv_objs="$recv_cmdline_objs $recv_errlist_objs"
 843 filter_objs="$filter_cmdline_objs $filter_errlist_objs"
 844 audiod_objs="$audiod_cmdline_objs $audiod_errlist_objs"
 845 server_objs="$server_cmdline_objs $server_errlist_objs"
 846 write_objs="$write_cmdline_objs $write_errlist_objs"
 847 client_objs="$client_cmdline_objs $client_errlist_objs"
 848 audioc_objs="$audioc_cmdline_objs $audioc_errlist_objs"
 849 afh_objs="$afh_cmdline_objs $afh_errlist_objs"
 850 fade_objs="$fade_cmdline_objs $fade_errlist_objs"
 851
 852 AC_SUBST(recv_objs, add_dot_o($recv_objs))
 853 AC_SUBST(recv_ldflags, $recv_ldflags)
 854 AC_DEFINE_UNQUOTED(INIT_RECV_ERRLISTS, objlist_to_errlist($recv_errlist_objs),
 855         errors used by para_recv)
 856
 857 AC_SUBST(filter_objs, add_dot_o($filter_objs))
 858 AC_SUBST(filter_ldflags, $filter_ldflags)
 859 AC_DEFINE_UNQUOTED(INIT_FILTER_ERRLISTS,
 860         objlist_to_errlist($filter_errlist_objs), errors used by para_filter)
 861
 862 AC_SUBST(audiod_objs, add_dot_o($audiod_objs))
 863 AC_SUBST(audiod_ldflags, $audiod_ldflags)
 864 AC_DEFINE_UNQUOTED(INIT_AUDIOD_ERRLISTS, objlist_to_errlist($audiod_errlist_objs),
 865         errors used by para_audiod)
 866
 867 AC_SUBST(server_objs, add_dot_o($server_objs))
 868 AC_SUBST(server_ldflags, $server_ldflags)
 869 AC_DEFINE_UNQUOTED(INIT_SERVER_ERRLISTS,
 870         objlist_to_errlist($server_errlist_objs), errors used by para_server)
 871
 872 AC_SUBST(afh_objs, add_dot_o($afh_objs))
 873 AC_SUBST(afh_ldflags, $afh_ldflags)
 874 AC_DEFINE_UNQUOTED(INIT_AFH_ERRLISTS,
 875         objlist_to_errlist($afh_errlist_objs), errors used by para_afh)
 876
 877 AC_SUBST(write_objs, add_dot_o($write_objs))
 878 AC_SUBST(write_ldflags, $write_ldflags)
 879 AC_DEFINE_UNQUOTED(INIT_WRITE_ERRLISTS,
 880         objlist_to_errlist($write_errlist_objs), errors used by para_write)
 881
 882 AC_SUBST(client_objs, add_dot_o($client_objs))
 883 AC_SUBST(client_ldflags, $client_ldflags)
 884 AC_DEFINE_UNQUOTED(INIT_CLIENT_ERRLISTS,
 885         objlist_to_errlist($client_errlist_objs), errors used by para_client)
 886
 887 AC_SUBST(audioc_objs, add_dot_o($audioc_objs))
 888 AC_SUBST(audioc_ldflags, $audioc_ldflags)
 889 AC_DEFINE_UNQUOTED(INIT_AUDIOC_ERRLISTS,
 890         objlist_to_errlist($audioc_errlist_objs), errors used by para_audioc)
 891
 892 AC_SUBST(gui_objs, add_dot_o($gui_objs))
 893 AC_DEFINE_UNQUOTED(INIT_GUI_ERRLISTS,
 894         objlist_to_errlist($gui_errlist_objs), errors used by para_gui)
 895
 896 AC_SUBST(fade_objs, add_dot_o($fade_objs))
 897 AC_SUBST(fade_ldflags, $fade_ldflags)
 898 AC_DEFINE_UNQUOTED(INIT_FADE_ERRLISTS,
 899         objlist_to_errlist($fade_errlist_objs), errors used by para_fade)
 900
 901
 902 enum="$(for i in $filters; do printf "${i}_FILTER, " | tr '[a-z]' '[A-Z]'; done)"
 903 AC_DEFINE_UNQUOTED(FILTER_ENUM, $enum NUM_SUPPORTED_FILTERS,
 904         enum of supported filters)
 905 inits="$(for i in $filters; do printf 'extern void '$i'_filter_init(struct filter *f); '; done)"
 906 AC_DEFINE_UNQUOTED(DECLARE_FILTER_INITS, $inits, init functions of the supported filters)
 907 array="$(for i in $filters; do printf '{.name = "'$i'", .init = '$i'_filter_init},'; done)"
 908 AC_DEFINE_UNQUOTED(FILTER_ARRAY, $array, array of supported filters)
 909
 910 enum="$(for i in $writers; do printf "${i}_WRITE, " | tr '[a-z]' '[A-Z]'; done)"
 911 AC_DEFINE_UNQUOTED(WRITER_ENUM, $enum NUM_SUPPORTED_WRITERS,
 912         enum of supported writers)
 913 AC_DEFINE_UNQUOTED(DEFAULT_WRITER, $default_writer, use this writer if none was specified)
 914 names="$(for i in $writers; do printf \"$i\",' ' ; done)"
 915 AC_DEFINE_UNQUOTED(WRITER_NAMES, $names, supported writer names)
 916 inits="$(for i in $writers; do printf 'extern void '$i'_write_init(struct writer *); '; done)"
 917 AC_DEFINE_UNQUOTED(DECLARE_WRITER_INITS, $inits, init functions of the supported writers)
 918 array="$(for i in $writers; do printf '{.init = '$i'_write_init},'; done)"
 919 AC_DEFINE_UNQUOTED(WRITER_ARRAY, $array, array of supported writers)
 920
 921 enum="$(for i in $audiod_audio_formats; do printf "AUDIO_FORMAT_${i}, " | tr '[a-z]' '[A-Z]'; done)"
 922 AC_DEFINE_UNQUOTED(AUDIOD_AUDIO_FORMATS_ENUM, $enum NUM_AUDIO_FORMATS,
 923         enum of audio formats supported by audiod)
 924 names="$(for i in $audiod_audio_formats; do printf \"$i\",' ' ; done)"
 925 AC_DEFINE_UNQUOTED(AUDIOD_AUDIO_FORMAT_ARRAY, $names, array of audio formats supported by audiod)
 926
 927 AC_OUTPUT
 928 AC_MSG_NOTICE([
 929 paraslash configuration:
 930 ~~~~~~~~~~~~~~~~~~~~~~~~
 931 unix socket credentials: $have_ucred
 932 audio formats supported by para_server/para_afh: $server_audio_formats
 933 id3 version2 support: $have_libid3tag
 934 filters supported by para_audiod/para_filter: $filters
 935 writers supported by para_audiod/para_write: $writers
 936 optional executables: $extras
 937 ])