configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.53)
   5
   6
   7 AC_INIT(paraslash, [git], maan@systemlinux.org)
   8 AC_CONFIG_HEADER([config.h])
   9
  10 ########################################################################### generic
  11 AC_PROG_CC
  12 AC_PROG_CPP
  13 AC_PROG_INSTALL
  14
  15 AC_HEADER_DIRENT
  16 AC_HEADER_STDC
  17 AC_HEADER_SYS_WAIT
  18 AC_CHECK_HEADERS([arpa/inet.h ctype.h fcntl.h limits.h netdb.h netinet/in.h stdlib.h \
  19         string.h sys/socket.h sys/time.h sys/timeb.h sys/un.h sys/ipc.h unistd.h utime.h malloc.h], \
  20         [], [AC_MSG_ERROR([$ac_header not found])])
  21
  22 AC_CHECK_HEADER(linux/soundcard.h, [extras="$extras para_fade"],
  23         [AC_MSG_WARN([linux/soundcard.h not found, \
  24         cannot build para_fade])])
  25
  26 # Checks for typedefs, structures, and compiler characteristics.
  27 AC_C_CONST
  28 AC_TYPE_OFF_T
  29 AC_TYPE_PID_T
  30 AC_TYPE_SIZE_T
  31 AC_HEADER_TIME
  32 AC_STRUCT_TM
  33
  34 # Checks for library functions.
  35 AC_FUNC_FORK
  36 AC_PROG_GCC_TRADITIONAL
  37 AC_FUNC_MALLOC
  38 AC_FUNC_MEMCMP
  39 AC_FUNC_MKTIME
  40 AC_FUNC_MMAP
  41 AC_FUNC_REALLOC
  42 AC_FUNC_SELECT_ARGTYPES
  43 AC_TYPE_SIGNAL
  44 AC_FUNC_STAT
  45 AC_FUNC_STRFTIME
  46 AC_FUNC_VPRINTF
  47 AC_CHECK_FUNCS([atexit dup2 gethostbyname inet_ntoa memchr memmove memset \
  48         regcomp select socket strchr strdup strerror strstr strtol uname], [],
  49         [AC_MSG_ERROR([function not found, cannot live without it])])
  50 ########################################################################### curses
  51 AC_CHECK_LIB([ncurses], [initscr], [],
  52         [AC_MSG_ERROR([libncurses not found])])
  53
  54 AC_CHECK_LIB([menu], [new_menu], [extras="$extras para_dbadm"],
  55         [AC_MSG_WARN([libmenu not found,  cannot build para_dbadm])])
  56
  57
  58 recv_cmdline_objs="recv.cmdline http_recv.cmdline dccp_recv.cmdline"
  59 recv_errlist_objs="http_recv recv_common recv time string net dccp_recv
  60         dccp fd"
  61 recv_ldflags=""
  62
  63 filter_cmdline_objs="filter.cmdline compress_filter.cmdline"
  64 filter_errlist_objs="filter_chain wav compress filter string"
  65 filter_ldflags=""
  66
  67 audiod_cmdline_objs="audiod.cmdline grab_client.cmdline compress_filter.cmdline
  68         http_recv.cmdline dccp_recv.cmdline"
  69 audiod_errlist_objs="audiod exec close_on_fork signal string daemon stat net
  70         time grab_client filter_chain wav compress http_recv dccp dccp_recv recv_common fd"
  71 audiod_ldflags=""
  72
  73 server_cmdline_objs="server.cmdline"
  74 server_errlist_objs="server mp3 afs command net string signal random_selector
  75         time daemon stat crypt http_send db close_on_fork playlist_selector
  76         ipc dccp dccp_send fd"
  77 server_ldflags=""
  78
  79 write_cmdline_objs="write.cmdline"
  80 write_errlist_objs="write write_common file_writer time fd string"
  81 write_ldflags=""
  82 write_writers="file"
  83
  84
  85 ########################################################################### ssl
  86 dnl @synopsis CHECK_SSL
  87 dnl
  88 dnl based on the follwing macro from the autoconf archive
  89 dnl
  90 dnl @category InstalledPackages
  91 dnl @author Mark Ethan Trostler <trostler@juniper.net>
  92 dnl @version 2003-01-28
  93 dnl @license AllPermissive
  94
  95 AC_DEFUN([CHECK_SSL],
  96 [
  97         for ssldir in $1 /usr/local/ssl /usr/lib/ssl /usr/ssl /usr/pkg /usr/local /usr; do
  98                 AC_MSG_CHECKING(for openssl in $ssldir)
  99                 if test -f "$ssldir/include/openssl/ssl.h"; then
 100                         found_ssl="yes"
 101                         AC_MSG_RESULT(yes)
 102                         SSL_CFLAGS="-I$ssldir/include/openssl"
 103                         SSL_CPPFLAGS="-I$ssldir/include/openssl"
 104                         break
 105                 fi
 106                 if test -f "$ssldir/include/ssl.h"; then
 107                         found_ssl="yes";
 108                         AC_MSG_RESULT(yes)
 109                         SSL_CFLAGS="-I$ssldir/include/";
 110                         SSL_CPPFLAGS="-I$ssldir/include/";
 111                         break
 112                 fi
 113                 AC_MSG_RESULT(no)
 114         done
 115         if test x_$found_ssl != x_yes; then
 116                 AC_MSG_ERROR(Cannot find ssl libraries)
 117         else
 118                 SSL_LIBS="-lssl -lcrypto";
 119                 SSL_LDFLAGS="-L$ssldir/lib";
 120         fi
 121         AC_SUBST(SSL_CPPFLAGS)
 122         AC_SUBST(SSL_CFLAGS)
 123         AC_SUBST(SSL_LIBS)
 124         AC_SUBST(SSL_LDFLAGS)
 125 ])dnl
 126
 127 AC_ARG_ENABLE(ssldir, [AS_HELP_STRING(--enable-ssldir=path,
 128                 [Search for openssl also in path.])])
 129 if test "$enable_ssldir" = "yes"; then enable_ssldir=""; fi
 130 CHECK_SSL($enable_ssldir)
 131 server_ldflags="$srver_ldflags $SSL_LDFLAGS $SSL_LIBS"
 132
 133 ########################################################################### ucred
 134
 135 AC_MSG_CHECKING(for struct ucred)
 136 AC_TRY_LINK([
 137         #include <sys/types.h>
 138         #include <sys/socket.h>
 139 ],[
 140         struct ucred sucred; sucred.pid=0;
 141 ],[have_ucred=yes],[have_ucred=no])
 142 AC_MSG_RESULT($have_ucred)
 143 if test ${have_ucred} = yes; then
 144         AC_DEFINE(HAVE_UCRED, 1, define to 1 you have struct ucred)
 145 fi
 146
 147 ########################################################################### gtk2
 148
 149 pkg_modules="gtk+-2.0 >= 2.0.0"
 150 PKG_CHECK_MODULES(GTK, [$pkg_modules], [extras="$extras para_krell.so"], [
 151         AC_MSG_WARN([gtk+-2 not found, can not build para_krell])
 152 ])
 153 AC_SUBST(GTK_CFLAGS)
 154 AC_SUBST(GTK_LIBS)
 155
 156 ########################################################################### sdl
 157 AC_CHECK_LIB([SDL_image], [SDL_Init], [extras="$extras para_sdl_gui"], [
 158         AC_MSG_WARN([libSDL_image not found, cannot build para_sdl_gui])
 159 ])
 160 AC_CHECK_HEADER(SDL/SDL.h, [],
 161         [AC_MSG_WARN([SDL/SDL.h not found])])
 162
 163 ########################################################################### mysql
 164 have_mysql="yes"
 165 AC_ARG_ENABLE(mysql_headers, [AC_HELP_STRING(--enable-mysql-headers=dir,
 166         [look for mysql.h also in dir])])
 167 if test -n "$enable_mysql_headers"; then
 168         mysql_cppflags="-I$enable_mysql_headers"
 169         CPPFLAGS="$CPPFLAGS $mysql_cppflags"
 170 fi
 171 AC_ARG_ENABLE(mysql_libs, [AC_HELP_STRING(--enable-mysql-libs=dir,
 172         [look for libmysqlclient also in dir])])
 173 if test -n "$enable_mysql_headers"; then
 174         mysql_libs="-L$enable_mysql_libs"
 175         LDFLAGS="$LDFLAGS $mysql_libs"
 176 fi
 177 AC_CHECK_HEADER(mysql/mysql.h, [], [
 178         have_mysql="no"
 179 ])
 180 AC_CHECK_LIB([mysqlclient], [mysql_init], [], [
 181         have_mysql="no"
 182 ])
 183 if test "$have_mysql" = "yes"; then
 184         server_ldflags="$server_ldflags $mysql_libs -lmysqlclient"
 185         server_errlist_objs="$server_errlist_objs mysql_selector"
 186         AC_SUBST(mysql_cppflags)
 187         AC_DEFINE(HAVE_MYSQL, 1, [define to 1 to turn on mysql support])
 188 else
 189         AC_MSG_WARN([cannot build mysql-based audio file selector])
 190 fi
 191 ########################################################################### ogg
 192 have_ogg="yes"
 193 AC_CHECK_LIB([ogg], [ogg_stream_init], [], [
 194         have_ogg="no"
 195 ])
 196 AC_CHECK_LIB([vorbis], [vorbis_info_init], [], [
 197         have_ogg="no"
 198 ])
 199 AC_CHECK_HEADERS([ogg/ogg.h vorbis/codec.h], [], [
 200         have_ogg="no"
 201 ])
 202 if test "$have_ogg" = "yes"; then
 203         AC_DEFINE(HAVE_OGGVORBIS, 1, define to 1 to turn on ogg vorbis support)
 204         server_ldflags="$server_ldflags -logg -lvorbis -lvorbisfile"
 205         filter_ldflags="$filter_ldflags -lvorbis -lvorbisfile"
 206         audiod_ldflags="$audiod_ldflags -lvorbis -lvorbisfile"
 207
 208         filter_cmdline_objs="$filter_cmdline_objs oggdec_filter.cmdline"
 209         audiod_cmdline_objs="$audiod_cmdline_objs oggdec_filter.cmdline"
 210
 211         server_errlist_objs="$server_errlist_objs ogg"
 212         filter_errlist_objs="$filter_errlist_objs oggdec"
 213         audiod_errlist_objs="$audiod_errlist_objs oggdec"
 214 else
 215         AC_MSG_WARN([no ogg vorbis support in para_server/para_filter])
 216 fi
 217 ########################################################################### faad
 218 have_faad=yes
 219 AC_CHECK_HEADER(neaacdec.h, [], have_faad=no)
 220 AC_CHECK_LIB([faad], [NeAACDecOpen], [], have_faad=no)
 221 if test "$have_faad" = "yes"; then
 222         AC_DEFINE(HAVE_FAAD, 1, define to 1 if you want to build the aacdec filter)
 223         filter_errlist_objs="$filter_errlist_objs aacdec"
 224         audiod_errlist_objs="$audiod_errlist_objs aacdec"
 225         filter_ldflags="$filter_ldflags -lfaad"
 226         audiod_ldflags="$audiod_ldflags -lfaad"
 227 else
 228         AC_MSG_WARN([no aac support in para_audiod/para_filter])
 229 fi
 230 ########################################################################### mad
 231 have_mad="yes"
 232 AC_CHECK_HEADERS([mad.h], [], [
 233         have_mad="no"
 234 ])
 235 AC_CHECK_LIB([mad], [mad_stream_init], [], [
 236         have_mad="no"
 237 ])
 238 if test "$have_mad" = "yes"; then
 239         AC_DEFINE(HAVE_MAD, 1, define to 1 if you want to build the mp3dec filter)
 240         filter_errlist_objs="$filter_errlist_objs mp3dec"
 241         audiod_errlist_objs="$audiod_errlist_objs mp3dec"
 242         filter_ldflags="$filter_ldflags -lmad"
 243         audiod_ldflags="$audiod_ldflags -lmad"
 244 else
 245         AC_MSG_WARN([no mp3dec support in para_audiod/para_filter])
 246 fi
 247 ########################################################################### alsa
 248 have_alsa="yes"
 249 msg="=> no alsa support for para_write"
 250 AC_CHECK_HEADERS([alsa/asoundlib.h], [], [
 251         AC_MSG_WARN([no alsa/asoundlib $msg])
 252         have_alsa="no"
 253 ])
 254 AC_CHECK_LIB([asound], [snd_pcm_open], [], [
 255         AC_MSG_WARN([no libasound $msg])
 256         have_alsa="no"
 257 ])
 258 if test "$have_alsa" = "yes"; then
 259         write_errlist_objs="$write_errlist_objs alsa_writer"
 260         write_ldflags="$write_ldflags -lasound"
 261         write_writers="$write_writers alsa"
 262 fi
 263 ########################################################################### ortp
 264 have_ortp="yes"
 265 AC_ARG_ENABLE(ortp, AC_HELP_STRING([--disable-ortp], [Disable ortp support]),
 266         if test x$enableval = xno; then
 267                 have_ortp=no
 268         fi
 269 )
 270 if test "$have_ortp" = "yes"; then
 271         AC_CHECK_HEADERS([ortp/ortp.h], [], [
 272                 have_ortp="no"
 273         ])
 274         AC_CHECK_LIB([ortp], [ortp_init], [], [
 275                 have_ortp="no"
 276         ])
 277 fi
 278 if test "$have_ortp" = "yes"; then
 279         recv_cmdline_objs="$recv_cmdline_objs ortp_recv.cmdline"
 280         recv_errlist_objs="$recv_errlist_objs ortp_recv"
 281
 282         audiod_cmdline_objs="$audiod_cmdline_objs ortp_recv.cmdline"
 283         audiod_errlist_objs="$audiod_errlist_objs ortp_recv"
 284
 285         server_errlist_objs="$server_errlist_objs ortp_send"
 286
 287         recv_ldflags="$recv_ldflags -lortp"
 288         server_ldflags="$server_ldflags -lortp"
 289         audiod_ldflags="$audiod_ldflags -lortp"
 290         AC_DEFINE(HAVE_ORTP, 1, [define to 1 to turn on ortp support])
 291
 292 else
 293         AC_MSG_NOTICE([deactivating ortp support])
 294 fi
 295 AC_SUBST(GLIB_CFLAGS)
 296 AC_SUBST(GLIB_LIBS)
 297
 298 ########################################################################### zmw
 299 slide="para_slider"
 300 msg="can not build para_slider"
 301 CPPFLAGS="$GTK_CFLAGS"
 302 LDFLAGS="$LDFLAGS $GTK_LIBS"
 303 AC_CHECK_HEADERS([zmw/zmw.h], [], [
 304         AC_MSG_WARN([zero memory widget header files not found, $msg])
 305         slide=""
 306 ])
 307 AC_CHECK_LIB([zmw], [zmw_init], [], [
 308         AC_MSG_WARN([zero memory widget library not found, $msg])
 309         slide=""
 310 ])
 311 extras="$extras $slide"
 312
 313
 314
 315
 316
 317 AC_SUBST(extra_binaries, [$extras])
 318 AC_SUBST(extra_filter_objs, [$extra_filter_objs])
 319 AC_SUBST(extra_filter_libs, [$extra_filter_libs])
 320 AC_SUBST(install_sh, [$INSTALL])
 321 AC_CONFIG_FILES([Makefile])
 322
 323
 324
 325 AC_DEFUN([add_dot_o],[$(for i in $@; do printf "$i.o "; done)])
 326 AC_DEFUN([objlist_to_errlist],[$(for i in $@; do printf "DEFINE_ERRLIST($(echo $i| tr 'a-z' 'A-Z'));"; done) [const char **para_errlist[[]]] = {$(for i in $@; do printf "PARA_ERRLIST($(echo $i | tr 'a-z' 'A-Z')), "; done) }])
 327
 328 recv_objs="$recv_cmdline_objs $recv_errlist_objs"
 329 filter_objs="$filter_cmdline_objs $filter_errlist_objs"
 330 audiod_objs="$audiod_cmdline_objs $audiod_errlist_objs"
 331 server_objs="$server_cmdline_objs $server_errlist_objs"
 332 write_objs="$write_cmdline_objs $write_errlist_objs"
 333
 334 AC_SUBST(recv_objs, add_dot_o($recv_objs))
 335 AC_SUBST(recv_ldflags, $recv_ldflags)
 336 AC_DEFINE_UNQUOTED(INIT_RECV_ERRLISTS, objlist_to_errlist($recv_errlist_objs),
 337         errors used by para_recv)
 338
 339 AC_SUBST(filter_objs, add_dot_o($filter_objs))
 340 AC_SUBST(filter_ldflags, $filter_ldflags)
 341 AC_DEFINE_UNQUOTED(INIT_FILTER_ERRLISTS,
 342         objlist_to_errlist($filter_errlist_objs), errors used by para_filter)
 343
 344 AC_SUBST(audiod_objs, add_dot_o($audiod_objs))
 345 AC_SUBST(audiod_ldflags, $audiod_ldflags)
 346 AC_DEFINE_UNQUOTED(INIT_AUDIOD_ERRLISTS, objlist_to_errlist($audiod_errlist_objs),
 347         errors used by para_audiod)
 348
 349 AC_SUBST(server_objs, add_dot_o($server_objs))
 350 AC_SUBST(server_ldflags, $server_ldflags)
 351 AC_DEFINE_UNQUOTED(INIT_SERVER_ERRLISTS,
 352         objlist_to_errlist($server_errlist_objs), errors used by para_server)
 353
 354 AC_SUBST(write_objs, add_dot_o($write_objs))
 355 AC_SUBST(write_ldflags, $write_ldflags)
 356 AC_DEFINE_UNQUOTED(INIT_WRITE_ERRLISTS,
 357         objlist_to_errlist($write_errlist_objs), errors used by para_write)
 358
 359 enum="$(for i in $write_writers; do printf "${i}_WRITE, " | tr '[a-z]' '[A-Z]'; done)"
 360 AC_DEFINE_UNQUOTED(WRITER_ENUM, $enum NUM_SUPPORTED_WRITERS,
 361         enum of supported writers)
 362 names="$(for i in $write_writers; do printf \"$i\",' ' ; done)"
 363 AC_DEFINE_UNQUOTED(WRITER_NAMES, $names, supported writer names)
 364 inits="$(for i in $write_writers; do printf 'extern void '$i'_writer_init(struct writer *); '; done)"
 365 AC_DEFINE_UNQUOTED(DECLARE_WRITER_INITS, $inits, init functions of the supported writers)
 366 array="$(for i in $write_writers; do printf '{.init = '$i'_writer_init},'; done)"
 367 AC_DEFINE_UNQUOTED(WRITER_ARRAY, $array, array of supported writers)
 368
 369 gui_cmdline_objs="gui.cmdline"
 370 gui_errlist_objs="exec close_on_fork signal string stat ringbuffer fd"
 371 gui_other_objs="gui gui_common gui_theme"
 372 gui_objs="$gui_cmdline_objs $gui_errlist_objs $gui_other_objs"
 373 AC_DEFINE_UNQUOTED(INIT_GUI_ERRLISTS,
 374         objlist_to_errlist($gui_errlist_objs), errors used by para_gui)
 375 AC_SUBST(gui_objs, add_dot_o($gui_objs))
 376
 377 AC_OUTPUT
 378 AC_MSG_NOTICE([creating Makefile.deps])
 379 gcc -MM -MG $mysql_cppflags *.c > Makefile.deps
 380 AC_MSG_NOTICE([
 381 paraslash configuration:
 382 ~~~~~~~~~~~~~~~~~~~~~~~~
 383 mysql support: $have_mysql
 384 ogg vorbis support: $have_ogg
 385 mp3dec support (libmad): $have_mad
 386 aac support (libfaad): $have_faad
 387 ortp support: $have_ortp
 388 unix socket credentials: $have_ucred
 389 supported writers for para_write: $write_writers
 390 ])