#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.60)


AC_INIT(paraslash, [git], maan@systemlinux.org)
AC_CONFIG_HEADER([config.h])

AC_PATH_PROG(UNAMEPATH, uname, no)
if test "$UNAMEPATH" = "no"; then
	AC_MSG_ERROR(unable to determine system type)
fi
AC_MSG_CHECKING(os type)
OSTYPE="`$UNAMEPATH -s`"
AC_MSG_RESULT("$OSTYPE")

AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL

AC_HEADER_DIRENT
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([arpa/inet.h ctype.h fcntl.h limits.h netdb.h netinet/in.h stdlib.h \
	string.h sys/socket.h sys/time.h sys/timeb.h sys/un.h sys/ipc.h unistd.h utime.h], \
	[], [AC_MSG_ERROR([$ac_header not found])])

AC_CHECK_HEADER(linux/soundcard.h, [extras="$extras para_fade"], 
	[AC_MSG_WARN([linux/soundcard.h not found, cannot build para_fade])])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_OFF_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
AC_STRUCT_TM

# Checks for library functions.
AC_FUNC_FORK
AC_PROG_GCC_TRADITIONAL
AC_FUNC_MALLOC
AC_FUNC_MEMCMP
AC_FUNC_MKTIME
AC_FUNC_MMAP
AC_FUNC_REALLOC
AC_FUNC_SELECT_ARGTYPES
AC_TYPE_SIGNAL
AC_FUNC_STAT
AC_FUNC_STRFTIME
AC_FUNC_VPRINTF
AC_CHECK_FUNCS([atexit dup2 gethostbyname inet_ntoa memchr memmove memset \
	regcomp select socket strchr strdup strerror strstr strtol uname], [], 
	[AC_MSG_ERROR([function not found, cannot live without it])])
########################################################################### curses
AC_CHECK_LIB([ncurses], [initscr], [], 
	[AC_MSG_ERROR([libncurses not found])])

AC_CHECK_LIB([menu], [new_menu], [extras="$extras para_dbadm"],
	[AC_MSG_WARN([libmenu not found,  cannot build para_dbadm])])


recv_cmdline_objs="recv.cmdline http_recv.cmdline dccp_recv.cmdline"
recv_errlist_objs="http_recv recv_common recv time string net dccp_recv
	dccp fd sched stdout"
recv_ldflags=""

receivers=" http dccp"
senders=" http dccp"
selectors=" random playlist"

filter_cmdline_objs="filter.cmdline compress_filter.cmdline"
filter_errlist_objs="filter_chain wav compress filter string stdin stdout sched fd"
filter_ldflags=""
filters=" compress wav"

audioc_cmdline_objs="audioc.cmdline"
audioc_errlist_objs="audioc string net fd"

audiod_cmdline_objs="audiod.cmdline grab_client.cmdline compress_filter.cmdline
	http_recv.cmdline dccp_recv.cmdline file_write.cmdline client.cmdline
	audiod_command_list"
audiod_errlist_objs="audiod signal string daemon stat net
	time grab_client filter_chain wav compress http_recv dccp dccp_recv
	recv_common fd sched write_common file_write audiod_command crypt
	client_common"
audiod_ldflags=""
audiod_audio_formats=""

server_cmdline_objs="server.cmdline server_command_list random_selector_command_list
	playlist_selector_command_list"
server_errlist_objs="server mp3_afh vss command net string signal random_selector
	time daemon stat crypt http_send db close_on_fork playlist_selector
	ipc dccp dccp_send fd user_list"
server_ldflags=""
server_audio_formats=" mp3"

write_cmdline_objs="write.cmdline file_write.cmdline"
write_errlist_objs="write write_common file_write time fd string sched stdin"
write_ldflags=""
writers=" file"

client_cmdline_objs="client.cmdline"
client_errlist_objs="client net string crypt fd sched stdin stdout client_common"
client_ldflags=""

########################################################################### ssl
dnl @synopsis CHECK_SSL
dnl
dnl based on the follwing macro from the autoconf archive
dnl
dnl @category InstalledPackages
dnl @author Mark Ethan Trostler <trostler@juniper.net>
dnl @version 2003-01-28
dnl @license AllPermissive

AC_DEFUN([CHECK_SSL],
[
	for ssldir in $1 /usr/local/ssl /usr/lib/ssl /usr/ssl /usr/pkg /usr/local /usr; do
		AC_MSG_CHECKING(for openssl in $ssldir)
		if test -f "$ssldir/include/openssl/ssl.h"; then
			found_ssl="yes"
			AC_MSG_RESULT(yes)
			SSL_CFLAGS="-I$ssldir/include/openssl"
			SSL_CPPFLAGS="-I$ssldir/include/openssl"
			break
		fi
		if test -f "$ssldir/include/ssl.h"; then
			found_ssl="yes";
			AC_MSG_RESULT(yes)
			SSL_CFLAGS="-I$ssldir/include/";
			SSL_CPPFLAGS="-I$ssldir/include/";
			break
		fi
		AC_MSG_RESULT(no)
	done
	if test x_$found_ssl != x_yes; then
		AC_MSG_ERROR(Cannot find ssl libraries)
	else
		SSL_LIBS="-lssl -lcrypto";
		SSL_LDFLAGS="-L$ssldir/lib";
	fi
	AC_SUBST(SSL_CPPFLAGS)
	AC_SUBST(SSL_CFLAGS)
	AC_SUBST(SSL_LIBS)
	AC_SUBST(SSL_LDFLAGS)
])dnl

AC_ARG_ENABLE(ssldir, [AS_HELP_STRING(--enable-ssldir=path,
	[Search for openssl also in path.])])
if test "$enable_ssldir" = "yes"; then enable_ssldir=""; fi
CHECK_SSL($enable_ssldir)
server_ldflags="$srver_ldflags $SSL_LDFLAGS $SSL_LIBS"
client_ldflags="$client_ldflags $SSL_LDFLAGS $SSL_LIBS"
audiod_ldflags="$audiod_ldflags $SSL_LDFLAGS $SSL_LIBS"

########################################################################### ucred
AC_MSG_CHECKING(for struct ucred)
AC_TRY_LINK([
	#include <sys/types.h>
	#include <sys/socket.h>
],[
	struct ucred sucred; sucred.pid=0;
],[have_ucred=yes],[have_ucred=no])
AC_MSG_RESULT($have_ucred)
if test ${have_ucred} = yes; then
	AC_DEFINE(HAVE_UCRED, 1, define to 1 you have struct ucred)
fi

########################################################################### osx

AC_MSG_CHECKING(for CoreAudio (MacOs))
AC_TRY_LINK([
	#include <CoreAudio/CoreAudio.h>
],[
	AudioDeviceID id;
],[have_core_audio=yes],[have_core_audio=no])
AC_MSG_RESULT($have_core_audio)
if test ${have_core_audio} = yes; then
	f1="-framework CoreAudio"
	f2="-framework AudioToolbox"
	f3="-framework AudioUnit"
	f4="-framework CoreServices"
	f="$f1 $f2 $f3 $f4"
	audiod_errlist_objs="$audiod_errlist_objs osx_write"
	audiod_cmdline_objs="$audiod_cmdline_objs osx_write.cmdline"
	audiod_ldflags="$audiod_ldflags $f"

	write_errlist_objs="$write_errlist_objs osx_write"
	write_cmdline_objs="$write_cmdline_objs osx_write.cmdline"
	write_ldflags="$write_ldflags $f"
	writers="$writers osx"
	AC_DEFINE(HAVE_CORE_AUDIO, 1, define to 1 on Mac Os X)
fi
########################################################################### gtk2
build_para_krell="yes"
OLD_CPPFLAGS="$CPPFLAGS"
OLD_LD_FLAGS="$LDFLAGS"
OLD_LIBS="$LIBS"
pkg_modules="gtk+-2.0 >= 2.0.0"
PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.0.4], [], [build_para_krell="no"])
PKG_CHECK_MODULES(GTK, [$pkg_modules], [], [build_para_krell="no"])
CPPFLAGS="$GTK_CFLAGS $GLIB_CFLAGS"
LDFLAGS="$LDFLAGS $GTK_LIBS"
AC_CHECK_HEADER(gkrellm2/gkrellm.h, [], [build_para_krell="no"])
if test "$build_para_krell" = "yes"; then
	AC_SUBST(GTK_CFLAGS)
	AC_SUBST(GTK_LIBS)
	extras="$extras para_krell.so"
else
	AC_MSG_WARN([can not build para_krell])
fi
CPPFLAGS="$OLD_CPPFLAGS"
LDFLAGS="$OLD_LDFLAGS"
LIBS="$OLD_LIBS"
########################################################################### sdl
# FIXME
AC_CHECK_LIB([SDL_image], [SDL_Init], [extras="$extras para_sdl_gui"], [
	AC_MSG_WARN([libSDL_image not found, cannot build para_sdl_gui])
])
AC_CHECK_HEADER(SDL/SDL.h, [], 
	[AC_MSG_WARN([SDL/SDL.h not found])])

########################################################################### mysql
have_mysql="yes"
OLD_CPPFLAGS="$CPPFLAGS"
OLD_LD_FLAGS="$LDFLAGS"
OLD_LIBS="$LIBS"
AC_ARG_WITH(mysql_headers, [AC_HELP_STRING(--with-mysql-headers=dir,
	[look for mysql.h also in dir])])
if test -n "$with_mysql_headers"; then
	mysql_cppflags="-I$with_mysql_headers"
	CPPFLAGS="$CPPFLAGS $mysql_cppflags"
fi
AC_ARG_WITH(mysql_libs, [AC_HELP_STRING(--with-mysql-libs=dir,
	[look for libmysqlclient also in dir])])
if test -n "$with_mysql_libs"; then
	mysql_libs="-L$with_mysql_libs"
	LDFLAGS="$LDFLAGS $mysql_libs"
fi
AC_CHECK_HEADER(mysql/mysql.h, [], [
	have_mysql="no"
])
AC_CHECK_LIB([mysqlclient], [mysql_init], [], [
	have_mysql="no"
])
if test "$have_mysql" = "yes"; then
	selectors="$selectors mysql"
	server_ldflags="$server_ldflags $mysql_libs -lmysqlclient"
	server_errlist_objs="$server_errlist_objs mysql_selector"
	server_cmdline_objs="$server_cmdline_objs mysql_selector_command_list"
	AC_SUBST(mysql_cppflags)
	AC_SUBST(mysql_libs)
	AC_DEFINE(HAVE_MYSQL, 1, [define to 1 to turn on mysql support])
else
	AC_MSG_WARN([cannot build mysql-based audio file selector])
fi
CPPFLAGS="$OLD_CPPFLAGS"
LDFLAGS="$OLD_LDFLAGS"
LIBS="$OLD_LIBS"
########################################################################### ogg
have_ogg="yes"
OLD_CPPFLAGS="$CPPFLAGS"
OLD_LD_FLAGS="$LDFLAGS"
OLD_LIBS="$LIBS"
AC_ARG_WITH(oggvorbis_headers, [AC_HELP_STRING(--with-oggvorbis-headers=dir,
	[look for vorbis/codec.h also in dir])])
if test -n "$with_oggvorbis_headers"; then
	oggvorbis_cppflags="-I$with_oggvorbis_headers"
	CPPFLAGS="$CPPFLAGS $oggvorbis_cppflags"
fi
AC_ARG_WITH(oggvorbis_libs, [AC_HELP_STRING(--with-oggvorbis-libs=dir,
	[look for oggvorbis libs also in dir])])
if test -n "$with_oggvorbis_libs"; then
	oggvorbis_libs="-L$with_oggvorbis_libs"
	LDFLAGS="$LDFLAGS $oggvorbis_libs"
fi

AC_CHECK_LIB([ogg], [ogg_stream_init], [], [ have_ogg="no" ])
AC_CHECK_LIB([vorbis], [vorbis_info_init], [], [ have_ogg="no" ])
AC_CHECK_HEADERS([ogg/ogg.h vorbis/codec.h], [], [ have_ogg="no" ])
if test "$have_ogg" = "yes"; then
	AC_DEFINE(HAVE_OGGVORBIS, 1, define to 1 to turn on ogg vorbis support)
	filters="$filters oggdec"
	if test "$OSTYPE" = "Darwin"; then
		oggvorbis_libs="-Wl,-bind_at_load  $oggvorbis_libs"
	fi
	server_ldflags="$server_ldflags $oggvorbis_libs -logg -lvorbis -lvorbisfile"
	filter_ldflags="$filter_ldflags $oggvorbis_libs -lvorbis -lvorbisfile"
	audiod_ldflags="$audiod_ldflags $oggvorbis_libs -lvorbis -lvorbisfile"

	filter_cmdline_objs="$filter_cmdline_objs oggdec_filter.cmdline"
	audiod_cmdline_objs="$audiod_cmdline_objs oggdec_filter.cmdline"

	server_errlist_objs="$server_errlist_objs ogg_afh"
	filter_errlist_objs="$filter_errlist_objs oggdec"
	audiod_errlist_objs="$audiod_errlist_objs oggdec"

	audiod_audio_formats="ogg"
	server_audio_formats="$server_audio_formats ogg"
	filter_filters="$filter_filters oggdec"
	AC_SUBST(oggvorbis_cppflags)
	AC_SUBST(oggvorbis_libs)
else
	AC_MSG_WARN([no ogg vorbis support in para_server/para_filter])
fi
CPPFLAGS="$OLD_CPPFLAGS"
LDFLAGS="$OLD_LDFLAGS"
LIBS="$OLD_LIBS"
########################################################################### faad
have_faad=yes
OLD_CPPFLAGS="$CPPFLAGS"
OLD_LD_FLAGS="$LDFLAGS"
OLD_LIBS="$LIBS"
AC_ARG_WITH(faad_headers, [AC_HELP_STRING(--with-faad-headers=dir,
	[look for neaacdec.h also in dir])])
if test -n "$with_faad_headers"; then
	faad_cppflags="-I$with_faad_headers"
	CPPFLAGS="$CPPFLAGS $faad_cppflags"
fi
AC_ARG_WITH(faad_libs, [AC_HELP_STRING(--with-faad-libs=dir,
	[look for libfaad also in dir])])
if test -n "$with_faad_libs"; then
	faad_libs="-L$with_faad_libs"
	LDFLAGS="$LDFLAGS $faad_libs"
fi
AC_CHECK_HEADER(neaacdec.h, [], have_faad=no)
AC_CHECK_LIB([faad], [NeAACDecOpen], [], have_faad=no)
if test "$have_faad" = "yes"; then
	AC_DEFINE(HAVE_FAAD, 1, define to 1 if you want to build the aacdec filter)
	filter_errlist_objs="$filter_errlist_objs aacdec aac_common"
	filter_filters="$filter_filters aacdec"
	audiod_errlist_objs="$audiod_errlist_objs aacdec aac_common"
	server_errlist_objs="$server_errlist_objs aac_afh aac_common"
	server_ldflags="$server_ldflags $faad_libs -lfaad"
	filter_ldflags="$filter_ldflags $faad_libs -lfaad"
	audiod_ldflags="$audiod_ldflags $faad_libs -lfaad"
	audiod_audio_formats="$audiod_audio_formats aac"
	server_audio_formats="$server_audio_formats aac"
	filters="$filters aacdec"
	AC_SUBST(faad_cppflags)
	AC_SUBST(faad_libs)
else
	AC_MSG_WARN([no aac support in para_audiod/para_filter])
fi
CPPFLAGS="$OLD_CPPFLAGS"
LDFLAGS="$OLD_LDFLAGS"
LIBS="$OLD_LIBS"
########################################################################### mad
have_mad="yes"
OLD_CPPFLAGS="$CPPFLAGS"
OLD_LD_FLAGS="$LDFLAGS"
OLD_LIBS="$LIBS"

AC_ARG_WITH(mad_headers, [AC_HELP_STRING(--with-mad-headers=dir,
	[look for mad.h also in dir])])
if test -n "$with_mad_headers"; then
	mad_cppflags="-I$with_mad_headers"
	CPPFLAGS="$CPPFLAGS $mad_cppflags"
fi
AC_ARG_WITH(mad_libs, [AC_HELP_STRING(--with-mad-libs=dir,
	[look for libmad also in dir])])
if test -n "$with_mad_libs"; then
	mad_libs="-L$with_mad_libs"
	LDFLAGS="$LDFLAGS $mad_libs"
fi
AC_CHECK_HEADERS([mad.h], [], [
	have_mad="no"
])
AC_CHECK_LIB([mad], [mad_stream_init], [], [
	have_mad="no"
])
if test "$have_mad" = "yes"; then
	AC_DEFINE(HAVE_MAD, 1, define to 1 if you want to build the mp3dec filter)
	filter_errlist_objs="$filter_errlist_objs mp3dec"
	audiod_errlist_objs="$audiod_errlist_objs mp3dec"
	filter_ldflags="$filter_ldflags $mad_libs -lmad"
	audiod_ldflags="$audiod_ldflags $mad_libs -lmad"
	audiod_audio_formats="$audiod_audio_formats mp3"
	filters="$filters mp3dec"
	AC_SUBST(mad_cppflags)
	AC_SUBST(mad_libs)
else
	AC_MSG_WARN([no mp3dec support in para_audiod/para_filter])
fi
if test -n "$audiod_audio_formats"; then
	extras="$extras para_audiod"
else
	AC_MSG_WARN([can not build para_audiod (no supported audio formats)])
fi
CPPFLAGS="$OLD_CPPFLAGS"
LDFLAGS="$OLD_LDFLAGS"
LIBS="$OLD_LIBS"
########################################################################### alsa
have_alsa="yes"
OLD_CPPFLAGS="$CPPFLAGS"
OLD_LD_FLAGS="$LDFLAGS"
OLD_LIBS="$LIBS"
msg="=> no alsa support for para_audiod/para_write"
AC_CHECK_HEADERS([alsa/asoundlib.h], [], [
	AC_MSG_WARN([no alsa/asoundlib $msg])
	have_alsa="no"
])
AC_CHECK_LIB([asound], [snd_pcm_open], [], [
	AC_MSG_WARN([no libasound $msg])
	have_alsa="no"
])
if test "$have_alsa" = "yes"; then
	audiod_errlist_objs="$audiod_errlist_objs alsa_write"
	audiod_cmdline_objs="$audiod_cmdline_objs alsa_write.cmdline"
	audiod_ldflags="$audiod_ldflags -lasound"

	write_errlist_objs="$write_errlist_objs alsa_write"
	write_cmdline_objs="$write_cmdline_objs alsa_write.cmdline"
	write_ldflags="$write_ldflags -lasound"
	writers="$writers alsa"
fi
CPPFLAGS="$OLD_CPPFLAGS"
LDFLAGS="$OLD_LDFLAGS"
LIBS="$OLD_LIBS"
########################################################################### ortp
have_ortp="yes"
OLD_CPPFLAGS="$CPPFLAGS"
OLD_LD_FLAGS="$LDFLAGS"
OLD_LIBS="$LIBS"
AC_ARG_WITH(ortp_headers, [AC_HELP_STRING(--with-ortp-headers=dir,
	[look for ortp/ortp.h also in dir])])
if test -n "$with_ortp_headers"; then
	ortp_cppflags="-I$with_ortp_headers"
	CPPFLAGS="$CPPFLAGS $ortp_cppflags"
fi
AC_ARG_WITH(ortp_libs, [AC_HELP_STRING(--with-ortp-libs=dir,
	[look for libortp also in dir])])
if test -n "$with_ortp_libs"; then
	ortp_libs="-L$with_ortp_libs"
	LDFLAGS="$LDFLAGS $ortp_libs"
fi
AC_CHECK_HEADERS([ortp/ortp.h], [], [have_ortp="no"])
AC_CHECK_LIB([ortp], [ortp_init], [], [have_ortp="no"])
if test "$have_ortp" = "yes"; then
	recv_cmdline_objs="$recv_cmdline_objs ortp_recv.cmdline"
	recv_errlist_objs="$recv_errlist_objs ortp_recv"

	audiod_cmdline_objs="$audiod_cmdline_objs ortp_recv.cmdline"
	audiod_errlist_objs="$audiod_errlist_objs ortp_recv"

	server_errlist_objs="$server_errlist_objs ortp_send"

	recv_ldflags="$recv_ldflags $ortp_libs -lortp"
	server_ldflags="$server_ldflags $ortp_libs -lortp"
	audiod_ldflags="$audiod_ldflags $ortp_libs -lortp"

	receivers="$receivers ortp"
	senders="$senders ortp"
	AC_DEFINE(HAVE_ORTP, 1, [define to 1 to turn on ortp support])
	AC_SUBST(ortp_cppflags)
	AC_SUBST(ortp_libs)
else
	AC_MSG_NOTICE([deactivating ortp sender/receiver])
fi
CPPFLAGS="$OLD_CPPFLAGS"
LDFLAGS="$OLD_LDFLAGS"
LIBS="$OLD_LIBS"
########################################################################### zmw
build_slider="yes"
OLD_CPPFLAGS="$CPPFLAGS"
OLD_LD_FLAGS="$LDFLAGS"
OLD_LIBS="$LIBS"
PKG_CHECK_MODULES(GTK, [$pkg_modules], [], [build_para_slider="no"])
PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.0.4], [], [build_slider="no"])
CPPFLAGS="$GTK_CFLAGS $GLIB_CFLAGS"
LDFLAGS="$LDFLAGS $GTK_LIBS"
AC_CHECK_HEADERS([zmw/zmw.h], [], [build_slider="no"])
AC_CHECK_LIB([zmw], [zmw_init], [], [build_slider="no"])
if test "$build_slider" = "no"; then
	AC_MSG_WARN([will not build para_slider])
else
	extras="$extras para_slider"
fi
CPPFLAGS="$OLD_CPPFLAGS"
LDFLAGS="$OLD_LDFLAGS"
LIBS="$OLD_LIBS"





AC_SUBST(extra_binaries, [$extras])
AC_SUBST(extra_filter_objs, [$extra_filter_objs])
AC_SUBST(extra_filter_libs, [$extra_filter_libs])
AC_SUBST(install_sh, [$INSTALL])
AC_CONFIG_FILES([Makefile])



AC_DEFUN([add_dot_o],[$(for i in $@; do printf "$i.o "; done)])
AC_DEFUN([objlist_to_errlist],[$(for i in $@; do printf "DEFINE_ERRLIST($(echo $i| tr 'a-z' 'A-Z'));"; done) [const char **para_errlist[[]]] = {$(for i in $@; do printf "PARA_ERRLIST($(echo $i | tr 'a-z' 'A-Z')), "; done) }])

recv_objs="$recv_cmdline_objs $recv_errlist_objs"
filter_objs="$filter_cmdline_objs $filter_errlist_objs"
audiod_objs="$audiod_cmdline_objs $audiod_errlist_objs"
server_objs="$server_cmdline_objs $server_errlist_objs"
write_objs="$write_cmdline_objs $write_errlist_objs"
client_objs="$client_cmdline_objs $client_errlist_objs"
audioc_objs="$audioc_cmdline_objs $audioc_errlist_objs"

AC_SUBST(recv_objs, add_dot_o($recv_objs))
AC_SUBST(recv_ldflags, $recv_ldflags)
AC_DEFINE_UNQUOTED(INIT_RECV_ERRLISTS, objlist_to_errlist($recv_errlist_objs),
	errors used by para_recv)

AC_SUBST(filter_objs, add_dot_o($filter_objs))
AC_SUBST(filter_ldflags, $filter_ldflags)
AC_DEFINE_UNQUOTED(INIT_FILTER_ERRLISTS,
	objlist_to_errlist($filter_errlist_objs), errors used by para_filter)

AC_SUBST(audiod_objs, add_dot_o($audiod_objs))
AC_SUBST(audiod_ldflags, $audiod_ldflags)
AC_DEFINE_UNQUOTED(INIT_AUDIOD_ERRLISTS, objlist_to_errlist($audiod_errlist_objs),
	errors used by para_audiod)

AC_SUBST(server_objs, add_dot_o($server_objs))
AC_SUBST(server_ldflags, $server_ldflags)
AC_DEFINE_UNQUOTED(INIT_SERVER_ERRLISTS,
	objlist_to_errlist($server_errlist_objs), errors used by para_server)

AC_SUBST(write_objs, add_dot_o($write_objs))
AC_SUBST(write_ldflags, $write_ldflags)
AC_DEFINE_UNQUOTED(INIT_WRITE_ERRLISTS,
	objlist_to_errlist($write_errlist_objs), errors used by para_write)

AC_SUBST(client_objs, add_dot_o($client_objs))
AC_SUBST(client_ldflags, $client_ldflags)
AC_DEFINE_UNQUOTED(INIT_CLIENT_ERRLISTS,
	objlist_to_errlist($client_errlist_objs), errors used by para_client)

AC_SUBST(audioc_objs, add_dot_o($audioc_objs))
AC_DEFINE_UNQUOTED(INIT_AUDIOC_ERRLISTS,
	objlist_to_errlist($audioc_errlist_objs), errors used by para_audioc)

enum="$(for i in $writers; do printf "${i}_WRITE, " | tr '[a-z]' '[A-Z]'; done)"
AC_DEFINE_UNQUOTED(WRITER_ENUM, $enum NUM_SUPPORTED_WRITERS,
	enum of supported writers)
names="$(for i in $writers; do printf \"$i\",' ' ; done)"
AC_DEFINE_UNQUOTED(WRITER_NAMES, $names, supported writer names)
inits="$(for i in $writers; do printf 'extern void '$i'_write_init(struct writer *); '; done)"
AC_DEFINE_UNQUOTED(DECLARE_WRITER_INITS, $inits, init functions of the supported writers)
array="$(for i in $writers; do printf '{.init = '$i'_write_init},'; done)"
AC_DEFINE_UNQUOTED(WRITER_ARRAY, $array, array of supported writers)
enum="$(for i in $audiod_audio_formats; do printf "AUDIO_FORMAT_${i}, " | tr '[a-z]' '[A-Z]'; done)"
AC_DEFINE_UNQUOTED(AUDIOD_AUDIO_FORMATS_ENUM, $enum NUM_AUDIO_FORMATS,
	enum of audio formats supported by audiod)
names="$(for i in $audiod_audio_formats; do printf \"$i\",' ' ; done)"
AC_DEFINE_UNQUOTED(AUDIOD_AUDIO_FORMAT_ARRAY, $names, array of audio formats supported by audiod)

gui_cmdline_objs="gui.cmdline"
gui_errlist_objs="exec close_on_fork signal string stat ringbuffer fd"
gui_other_objs="gui gui_common gui_theme"
gui_objs="$gui_cmdline_objs $gui_errlist_objs $gui_other_objs"
AC_DEFINE_UNQUOTED(INIT_GUI_ERRLISTS,
	objlist_to_errlist($gui_errlist_objs), errors used by para_gui)
AC_SUBST(gui_objs, add_dot_o($gui_objs))

AC_OUTPUT
AC_MSG_NOTICE([creating Makefile.deps])
gcc -MM -MG $mysql_cppflags $faad_cppflags $mad_cppflags $ortp_cppflags $oggvorbis_cppflags *.c > Makefile.deps
AC_MSG_NOTICE([
paraslash configuration:
~~~~~~~~~~~~~~~~~~~~~~~~
unix socket credentials: $have_ucred
audio file selectors supported by para_server: $selectors
audio formats supported by para_server: $server_audio_formats
senders supported by para_server/para_send: $senders
receivers supported by para_audiod/para_recv: $receivers
filters supported by para_audiod/para_filter: $filters
writers supported by para_audiod/para_write: $writers
optional executables: $extras
])