configure.ac

   1 AC_PREREQ([2.61])
   2
   3 AC_INIT([paraslash], [m4_esyscmd_s(./GIT-VERSION-GEN)],
   4         [maan@tuebingen.mpg.de], [], [http://people.tuebingen.mpg.de/maan/paraslash/])
   5 AC_CONFIG_HEADERS([config.h])
   6
   7 AC_CONFIG_FILES([Makefile])
   8 AC_DEFUN([add_dot_o],[$(for i in $@; do printf "$i.o "; done)])
   9 AC_DEFUN([LIB_ARG_WITH], [
  10         AC_ARG_WITH($1-headers, [AS_HELP_STRING(--with-$1-headers=dir,
  11                 [look for $1 headers in dir])])
  12         AC_ARG_WITH($1-libs, [AS_HELP_STRING(--with-$1-libs=dir,
  13                 [look for $1 libraries in dir])])
  14         if test -n "$with_$1_headers"; then
  15                 $1_cppflags="-I$with_$1_headers"
  16                 CPPFLAGS="$CPPFLAGS $$1_cppflags"
  17         fi
  18         if test -n "$with_$1_libs"; then
  19                 $1_ldflags="-L$with_$1_libs $2"
  20         else
  21                 $1_ldflags="$2"
  22         fi
  23         LDFLAGS="$LDFLAGS $$1_ldflags"
  24 ])
  25
  26 AC_DEFUN([STASH_FLAGS], [
  27         OLD_CPPFLAGS="$CPPFLAGS"
  28         OLD_LDFLAGS="$LDFLAGS"
  29         OLD_LIBS="$LIBS"
  30 ])
  31
  32 AC_DEFUN([UNSTASH_FLAGS], [
  33         CPPFLAGS="$OLD_CPPFLAGS"
  34         LDFLAGS="$OLD_LDFLAGS"
  35         LIBS="$OLD_LIBS"
  36 ])
  37 AC_DEFUN([LIB_SUBST_FLAGS], [
  38         if test "$HAVE_[]m4_toupper([$1])" = 'yes'; then
  39                 AC_DEFINE(HAVE_[]m4_toupper([$1]), 1,
  40                         define to 1 to turn on $1 support)
  41                 AC_SUBST(HAVE_[]m4_toupper([$1]))
  42         else
  43                 $1_cppflags=
  44                 $1_ldflags=
  45         fi
  46         AC_SUBST(HAVE_[]m4_toupper([$1]))
  47         AC_SUBST($1_cppflags)
  48         AC_SUBST($1_ldflags)
  49 ])
  50 AC_DEFUN([REQUIRE_EXECUTABLE], [
  51         AC_PATH_PROG(m4_toupper([$1]), [$1])
  52         test -z "$m4_toupper([$1])" && AC_MSG_ERROR(
  53                 [$1 is required to build this package])
  54 ])
  55
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AC_C_BIGENDIAN()
  58 AC_PROG_CC
  59 AC_PROG_CPP
  60
  61 REQUIRE_EXECUTABLE([bison])
  62 REQUIRE_EXECUTABLE([flex])
  63 REQUIRE_EXECUTABLE([m4])
  64
  65 executables="recv filter audioc write afh play"
  66 ########################################################################### osl
  67 STASH_FLAGS
  68 LIB_ARG_WITH([osl], [-losl])
  69 HAVE_OSL=yes
  70 AC_CHECK_HEADER(osl.h, [], [HAVE_OSL=no])
  71 AC_CHECK_LIB([osl], [osl_open_table], [], [HAVE_OSL=no])
  72 LIB_SUBST_FLAGS(osl)
  73 UNSTASH_FLAGS
  74 ######################################################################## lopsub
  75 HAVE_LOPSUB=yes
  76 AC_PATH_PROG([LOPSUBGEN], [lopsubgen])
  77 test -z "$LOPSUBGEN" && HAVE_LOPSUB=no
  78 STASH_FLAGS
  79 LIB_ARG_WITH([lopsub], [-llopsub])
  80 AC_CHECK_HEADER(lopsub.h, [], [HAVE_LOPSUB=no])
  81 AC_CHECK_LIB([lopsub], [lls_merge], [], [HAVE_LOPSUB=no])
  82 if test $HAVE_LOPSUB = no; then AC_MSG_ERROR([
  83         The lopsub library is required to build this software, but
  84         the above checks indicate it is not installed on your system.
  85         Run the following command to download a copy.
  86                 git clone git://git.tuebingen.mpg.de/lopsub.git
  87         Install the library, then run this configure script again.
  88 ])
  89 fi
  90 LIB_SUBST_FLAGS([lopsub])
  91 UNSTASH_FLAGS
  92 ######################################################################## openssl
  93 STASH_FLAGS
  94 HAVE_OPENSSL=yes
  95 LIB_ARG_WITH([openssl], [-lssl -lcrypto])
  96 AC_CHECK_HEADER(openssl/ssl.h, [], [HAVE_OPENSSL=no])
  97 AC_CHECK_LIB([crypto], [RAND_bytes], [], [HAVE_OPENSSL=no])
  98 LIB_SUBST_FLAGS(openssl)
  99 if test $HAVE_OPENSSL = yes; then
 100         HAVE_RSA_SET0_KEY=yes
 101         AC_CHECK_DECL([RSA_set0_key], [], [], [#include <openssl/rsa.h>])
 102         AC_CHECK_LIB([crypto], [RSA_set0_key], [], [])
 103         if test "$ac_cv_have_decl_RSA_set0_key" != "$ac_cv_lib_crypto_RSA_set0_key"; then
 104                 AC_MSG_ERROR([openssl header/library mismatch])
 105         fi
 106         if test "$ac_cv_have_decl_RSA_set0_key" = yes; then
 107                 AC_DEFINE([HAVE_RSA_SET0_KEY], [1], [openssl >= 1.1])
 108         else
 109                 AC_MSG_WARN([
 110         Old openssl library detected. Support for openssl-1.0 and earlier
 111         will be removed in the next major paraslash release. Please upgrade
 112         your openssl installation.])
 113         fi
 114         HAVE_CRYPTO_CLEANUP_ALL_EX_DATA=yes
 115         AC_CHECK_DECL([CRYPTO_cleanup_all_ex_data], [],
 116                 [HAVE_CRYPTO_CLEANUP_ALL_EX_DATA=no],
 117                 [#include <openssl/rsa.h>])
 118         AC_CHECK_LIB([crypto], [CRYPTO_cleanup_all_ex_data], [],
 119                 [HAVE_CRYPTO_CLEANUP_ALL_EX_DATA=no])
 120         test $HAVE_CRYPTO_CLEANUP_ALL_EX_DATA = yes &&
 121                 AC_DEFINE([HAVE_CRYPTO_CLEANUP_ALL_EX_DATA], [1],
 122                         [not available on FreeBSD 12])
 123         HAVE_OPENSSL_THREAD_STOP=yes
 124         AC_CHECK_DECL([OPENSSL_thread_stop], [],
 125                 [HAVE_OPENSSL_THREAD_STOP=no],
 126                 [#include <openssl/crypto.h>])
 127         AC_CHECK_LIB([crypto], [OPENSSL_thread_stop], [],
 128                 [HAVE_OPENSSL_THREAD_STOP=no])
 129         test $HAVE_OPENSSL_THREAD_STOP = yes &&
 130                 AC_DEFINE([HAVE_OPENSSL_THREAD_STOP], [1],
 131                         [not available on openssl-1.0])
 132 fi
 133 UNSTASH_FLAGS
 134 ######################################################################### gcrypt
 135 STASH_FLAGS
 136 HAVE_GCRYPT=yes
 137 LIB_ARG_WITH([gcrypt], [-lgcrypt])
 138 AC_CHECK_HEADER(gcrypt.h, [], [HAVE_GCRYPT=no])
 139 AC_CHECK_LIB([gcrypt], [gcry_randomize], [], [HAVE_GCRYPT=no])
 140 LIB_SUBST_FLAGS(gcrypt)
 141 UNSTASH_FLAGS
 142 ######################################################################### crypto
 143 AC_ARG_ENABLE(cryptolib, [AS_HELP_STRING(--enable-cryptolib=lib, [
 144         Force using crypto library "lib". This package requires either
 145         openssl or libgcrypt being installed. Possible values for "lib"
 146         are thus "openssl" and "gcrypt". If this option is not given,
 147         openssl is tried first. If openssl was not found, gcrypt is
 148         tried next.])])
 149
 150 CRYPTOLIB="$enable_cryptolib"
 151 case "$enable_cryptolib" in
 152 "openssl")
 153         test $HAVE_OPENSSL = no && AC_MSG_ERROR(openssl not found)
 154         crypto_ldflags="$openssl_ldflags"
 155         ;;
 156 "gcrypt")
 157         test $HAVE_GCRYPT = no && AC_MSG_ERROR(gcrypt not found)
 158         crypto_ldflags="$gcrypt_ldflags"
 159         ;;
 160 "")
 161         crypto_ldflags=
 162         if test $HAVE_GCRYPT = yes; then
 163                 CRYPTOLIB=gcrypt
 164                 crypto_ldflags="$gcrypt_ldflags"
 165         fi
 166         if test $HAVE_OPENSSL = yes; then
 167                 CRYPTOLIB=openssl
 168                 crypto_ldflags="$openssl_ldflags"
 169         fi
 170         ;;
 171 *)
 172         AC_MSG_ERROR([invalid value "$enable_cryptolib" for --enable-cryptolib])
 173         ;;
 174 esac
 175 AC_SUBST(crypto_ldflags)
 176 AC_SUBST(CRYPTOLIB)
 177 ########################################################################## iconv
 178 STASH_FLAGS
 179 LIBS=
 180 AC_SEARCH_LIBS([libiconv_open], [iconv],
 181         [iconv_ldflags="$LIBS"],
 182         []
 183 )
 184 AC_SUBST(iconv_ldflags)
 185 AC_MSG_CHECKING([whether iconv needs const char ** cast])
 186 AC_COMPILE_IFELSE([
 187         AC_LANG_PROGRAM([
 188                 #include <iconv.h>
 189         ],[
 190                 size_t iconv(iconv_t cd, const char **inbuf,
 191                         size_t *inbytesleft, char **outbuf,
 192                         size_t *outbytesleft);
 193         ])
 194 ],
 195         [cast='(const char **)'; msg=yes],
 196         [cast=; msg=no]
 197 )
 198 AC_DEFINE_UNQUOTED(ICONV_CAST, $cast, [cast for second arg to iconv()])
 199 AC_MSG_RESULT($msg)
 200 UNSTASH_FLAGS
 201 ########################################################################### ucred
 202 AC_CHECK_TYPE([struct ucred], [
 203         AC_DEFINE(HAVE_UCRED, 1, define to 1 you have struct ucred)
 204 ], [], [
 205         #include <sys/types.h>
 206         #include <sys/socket.h>
 207 ])
 208 ################################################################### FNM_EXTMATCH
 209 AC_MSG_CHECKING(for extended wildcard pattern matching)
 210 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 211         #include <fnmatch.h>
 212 ]], [[
 213         unsigned n = FNM_EXTMATCH;
 214 ]])], [have_fnm_extmatch=yes], [have_fnm_extmatch=no])
 215 AC_MSG_RESULT($have_fnm_extmatch)
 216 if test $have_fnm_extmatch = yes; then
 217         AC_DEFINE(HAVE_FNM_EXTMATCH, 1, define to 1 if FNM_EXTMATCH is defined)
 218 fi
 219 ########################################################################### curses
 220 STASH_FLAGS
 221 LIB_ARG_WITH([curses], [])
 222 HAVE_CURSES=yes
 223 AC_CHECK_HEADER(curses.h, [], [HAVE_CURSES=no])
 224 AC_SEARCH_LIBS([initscr], [ncursesw curses], [], [HAVE_CURSES=no])
 225 curses_ldflags="$curses_ldflags $LIBS"
 226 LIB_SUBST_FLAGS(curses)
 227 UNSTASH_FLAGS
 228 ########################################################################### ip_mreqn
 229 AC_CHECK_TYPE([struct ip_mreqn], [
 230         AC_DEFINE(HAVE_IP_MREQN, 1, define to 1 if you have struct ip_mreqn)
 231 ], [], [
 232         #include <netdb.h>
 233         #include <net/if.h>
 234 ])
 235 ########################################################################### ogg
 236 STASH_FLAGS
 237 LIB_ARG_WITH([ogg], [-logg])
 238 HAVE_OGG=yes
 239 AC_CHECK_HEADERS([ogg/ogg.h], [], [HAVE_OGG=no])
 240 AC_CHECK_LIB([ogg], [ogg_stream_init], [], [HAVE_OGG=no])
 241 AC_CHECK_LIB([ogg], [ogg_stream_flush_fill], [
 242         AC_DEFINE(HAVE_OGG_STREAM_FLUSH_FILL, 1, [libogg >= 1.3.0])])
 243 LIB_SUBST_FLAGS(ogg)
 244 UNSTASH_FLAGS
 245 ######################################################################### vorbis
 246 STASH_FLAGS
 247 LIB_ARG_WITH([vorbis], [-lvorbis -lvorbisfile])
 248 HAVE_VORBIS=yes
 249 AC_CHECK_HEADERS([vorbis/codec.h], [], [HAVE_VORBIS=no])
 250 AC_CHECK_LIB([vorbis], [vorbis_info_init], [], [HAVE_VORBIS=no])
 251 LIB_SUBST_FLAGS(vorbis)
 252 UNSTASH_FLAGS
 253 ######################################################################### speex
 254 STASH_FLAGS
 255 LIB_ARG_WITH([speex], [-lspeex])
 256 HAVE_SPEEX=yes
 257 AC_CHECK_HEADERS([speex/speex.h], [], [HAVE_SPEEX=no])
 258 AC_CHECK_LIB([speex], [speex_decoder_init], [], [HAVE_SPEEX=no])
 259 LIB_SUBST_FLAGS(speex)
 260 UNSTASH_FLAGS
 261 ######################################################################### opus
 262 STASH_FLAGS
 263 LIB_ARG_WITH([opus], [-lopus])
 264 HAVE_OPUS=yes
 265 AC_CHECK_HEADERS([opus/opus.h], [], [HAVE_OPUS=no])
 266 AC_CHECK_LIB([opus], [opus_multistream_decode], [], [HAVE_OPUS=no])
 267 LIB_SUBST_FLAGS(opus)
 268 UNSTASH_FLAGS
 269 ########################################################################### flac
 270 STASH_FLAGS
 271 LIB_ARG_WITH([flac], [-lFLAC -lm])
 272 HAVE_FLAC=yes
 273 AC_CHECK_HEADER(FLAC/stream_decoder.h, [], HAVE_FLAC=no)
 274 AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_init_file], [], HAVE_FLAC=no)
 275 LIB_SUBST_FLAGS(flac)
 276 UNSTASH_FLAGS
 277
 278 # some helpers for the ogg container format
 279 AS_IF([test "$HAVE_OGG" = 'yes' -a \( \
 280                  "$HAVE_VORBIS" = 'yes' \
 281                 -o "$HAVE_SPEEX" = 'yes' \
 282                 -o "$HAVE_OPUS" = 'yes' \
 283                 -o "$HAVE_FLAC" = 'yes' \
 284 \)], [NEED_OGG_OBJECTS=yes], [NEED_OGG_OBJECTS=no])
 285 AC_SUBST([NEED_OGG_OBJECTS])
 286 AS_IF([test "$HAVE_OGG" = 'yes' -a "$HAVE_VORBIS" = 'yes'],
 287         [NEED_VORBIS_OBJECTS=yes], [NEED_VORBIS_OBJECTS=no])
 288 AC_SUBST([NEED_VORBIS_OBJECTS])
 289 AS_IF([test "$HAVE_OGG" = 'yes' -a "$HAVE_SPEEX" = 'yes'],
 290         [NEED_SPEEX_OBJECTS=yes], [NEED_SPEEX_OBJECTS=no])
 291 AC_SUBST([NEED_SPEEX_OBJECTS])
 292 AS_IF([test "$HAVE_OGG" = 'yes' -a "$HAVE_OPUS" = 'yes'],
 293         [NEED_OPUS_OBJECTS=yes], [NEED_OPUS_OBJECTS=no])
 294 AC_SUBST([NEED_OPUS_OBJECTS])
 295 AS_IF([test "$HAVE_OGG" = 'yes' -a "$HAVE_FLAC" = 'yes'],
 296         [NEED_FLAC_OBJECTS=yes], [NEED_FLAC_OBJECTS=no])
 297 AC_SUBST([NEED_FLAC_OBJECTS])
 298 ########################################################################### faad
 299 STASH_FLAGS
 300 LIB_ARG_WITH([faad], [-lfaad])
 301 HAVE_FAAD=yes
 302 AC_CHECK_HEADER(neaacdec.h, [], HAVE_FAAD=no)
 303 AC_CHECK_LIB([faad], [NeAACDecOpen], [], HAVE_FAAD=no)
 304 LIB_SUBST_FLAGS(faad)
 305 UNSTASH_FLAGS
 306 ########################################################################### mad
 307 STASH_FLAGS
 308 LIB_ARG_WITH([mad], [-lmad])
 309 HAVE_MAD=yes
 310 AC_CHECK_HEADER(mad.h, [], HAVE_MAD=no)
 311 AC_CHECK_LIB([mad], [mad_stream_init], [], HAVE_MAD=no)
 312 LIB_SUBST_FLAGS(mad)
 313 UNSTASH_FLAGS
 314 ###################################################################### libid3tag
 315 STASH_FLAGS
 316 LIB_ARG_WITH([id3tag], [-lid3tag -lz])
 317 HAVE_ID3TAG=yes
 318 AC_CHECK_HEADER(id3tag.h, [], HAVE_ID3TAG=no)
 319 AC_CHECK_LIB([id3tag], [id3_file_fdopen], [], HAVE_ID3TAG=no)
 320 LIB_SUBST_FLAGS(id3tag)
 321 UNSTASH_FLAGS
 322 ########################################################################### oss
 323 STASH_FLAGS
 324 LIB_ARG_WITH([oss], [])
 325 AC_CHECK_HEADER(sys/soundcard.h, [HAVE_OSS=yes], [HAVE_OSS=no])
 326 AC_CHECK_LIB(ossaudio, _oss_ioctl, [oss_ldflags="$oss_ldflags -lossaudio"], [])
 327 LIB_SUBST_FLAGS(oss)
 328 UNSTASH_FLAGS
 329 ########################################################################### alsa
 330 STASH_FLAGS
 331 LIB_ARG_WITH([alsa], [-lasound])
 332 HAVE_ALSA=yes
 333 AC_CHECK_HEADER(alsa/asoundlib.h, [], HAVE_ALSA=no)
 334 AC_CHECK_LIB([asound], [snd_pcm_open], [], HAVE_ALSA=no)
 335 LIB_SUBST_FLAGS(alsa)
 336 UNSTASH_FLAGS
 337 ######################################################################### pthread
 338 STASH_FLAGS
 339 LIB_ARG_WITH([pthread], [-lpthread])
 340 HAVE_PTHREAD=yes
 341 AC_CHECK_HEADER(pthread.h, [], HAVE_PTHREAD=no)
 342 AC_CHECK_LIB([pthread], [pthread_create], [], HAVE_PTHREAD=no)
 343 LIB_SUBST_FLAGS(pthread)
 344 UNSTASH_FLAGS
 345 ########################################################################### libao
 346 STASH_FLAGS
 347 LIB_ARG_WITH([ao], [-lao])
 348 HAVE_AO=yes
 349 AC_CHECK_HEADER(ao/ao.h, [], HAVE_AO=no)
 350 AC_CHECK_LIB([ao], [ao_initialize], [], HAVE_AO=no)
 351 LIB_SUBST_FLAGS(ao)
 352 UNSTASH_FLAGS
 353 AS_IF([test $HAVE_AO = yes -a $HAVE_PTHREAD = yes],
 354         [NEED_AO_OBJECTS]=yes, [NEED_AO_OBJECTS=no])
 355 AC_SUBST([NEED_AO_OBJECTS])
 356 ######################################################################## readline
 357 STASH_FLAGS
 358 AC_SEARCH_LIBS([tgetent], [tinfo curses terminfo termcap])
 359 LIB_ARG_WITH([readline], [-lreadline $LIBS])
 360 HAVE_READLINE=yes
 361 AC_CHECK_HEADER([readline/readline.h], [], [HAVE_READLINE=no])
 362 AC_CHECK_LIB([readline], [rl_free_keymap], [], HAVE_READLINE=no)
 363 AC_CHECK_DECL(
 364         [rl_free_keymap],
 365         [AC_DEFINE(RL_FREE_KEYMAP_DECLARED, 1, readline >= 6.3)],
 366         [],
 367         [
 368                 #include <stdio.h>
 369                 #include <readline/readline.h>
 370         ]
 371 )
 372 LIB_SUBST_FLAGS(readline)
 373 UNSTASH_FLAGS
 374 ############################################################# libsamplerate
 375 STASH_FLAGS
 376 LIB_ARG_WITH([samplerate], [-lsamplerate])
 377 HAVE_SAMPLERATE=yes
 378 AC_CHECK_HEADER(samplerate.h, [], HAVE_SAMPLERATE=no)
 379 AC_CHECK_LIB([samplerate], [src_process], [], HAVE_SAMPLERATE=no)
 380 LIB_SUBST_FLAGS(samplerate)
 381 UNSTASH_FLAGS
 382 ######################################################################### ubsan
 383 AC_ARG_ENABLE([ubsan], [AS_HELP_STRING(--enable-ubsan,
 384         [Detect and report undefined behaviour.])],
 385         [ENABLE_UBSAN=yes], [ENABLE_UBSAN=no])
 386 AC_SUBST(ENABLE_UBSAN)
 387 ######################################################### server and upgrade_db
 388 if test -n "$CRYPTOLIB" && test $HAVE_OSL = yes; then
 389         build_server="yes"
 390         executables="$executables server upgrade_db"
 391 else
 392         build_server="no"
 393 fi
 394 ############################################################# client
 395 if test -n "$CRYPTOLIB"; then
 396         build_client="yes"
 397         executables="$executables client"
 398 else
 399         build_client="no"
 400 fi
 401 ############################################################# audiod
 402 if test -n "$CRYPTOLIB"; then
 403         build_audiod="yes"
 404         executables="$executables audiod"
 405 else
 406         build_audiod="no"
 407 fi
 408 ########################################################################### mixer
 409 if test $HAVE_OSS = yes -o $HAVE_ALSA = yes; then
 410         build_mixer="yes"
 411         executables="$executables mixer"
 412 fi
 413 ########################################################################### gui
 414 if test $HAVE_CURSES = yes; then
 415         build_gui="yes"
 416         executables="$executables gui"
 417 fi
 418 ######################################################################## filter
 419 filter_objs="
 420         filter_common
 421         wav_filter
 422         compress_filter
 423         filter
 424         string
 425         stdin
 426         stdout
 427         sched
 428         fd
 429         amp_filter
 430         fecdec_filter
 431         fec
 432         lsu
 433         version
 434         prebuffer_filter
 435         time
 436         bitstream
 437         imdct
 438         wma_common
 439         wmadec_filter
 440         buffer_tree
 441         net
 442         sync_filter
 443 "
 444 AS_IF([test $NEED_VORBIS_OBJECTS = yes],
 445         [filter_objs="$filter_objs oggdec_filter"])
 446 AS_IF([test $NEED_SPEEX_OBJECTS = yes],
 447         [filter_objs="$filter_objs spxdec_filter spx_common"])
 448 AS_IF([test $NEED_OPUS_OBJECTS = yes],
 449         [filter_objs="$filter_objs opusdec_filter opus_common"])
 450 AS_IF([test $NEED_FLAC_OBJECTS = yes],
 451         [filter_objs="$filter_objs flacdec_filter"])
 452 if test $HAVE_FAAD = yes; then
 453         filter_objs="$filter_objs aacdec_filter"
 454 fi
 455 if test $HAVE_MAD = yes; then
 456         filter_objs="$filter_objs mp3dec_filter"
 457 fi
 458 if test $HAVE_SAMPLERATE = yes; then
 459         filter_objs="$filter_objs resample_filter check_wav"
 460 fi
 461 AC_SUBST(filter_objs, add_dot_o($filter_objs))
 462 ########################################################################### afh
 463 audio_format_handlers="mp3 wma"
 464 afh_objs="
 465         afh
 466         string
 467         fd
 468         mp3_afh
 469         afh_common
 470         time
 471         wma_afh
 472         wma_common
 473         version
 474 "
 475 AS_IF([test $NEED_OGG_OBJECTS = yes], [afh_objs="$afh_objs ogg_afh_common"])
 476 AS_IF([test $NEED_VORBIS_OBJECTS = yes], [
 477         afh_objs="$afh_objs ogg_afh"
 478         audio_format_handlers="$audio_format_handlers ogg"
 479 ])
 480 AS_IF([test $NEED_SPEEX_OBJECTS = yes], [
 481         afh_objs="$afh_objs spx_afh spx_common"
 482         audio_format_handlers="$audio_format_handlers spx"
 483 ])
 484 AS_IF([test $NEED_OPUS_OBJECTS = yes], [
 485         afh_objs="$afh_objs opus_afh opus_common"
 486         audio_format_handlers="$audio_format_handlers opus"
 487 ])
 488 AS_IF([test $NEED_FLAC_OBJECTS = yes], [
 489         afh_objs="$afh_objs flac_afh"
 490         audio_format_handlers="$audio_format_handlers flac"
 491 ])
 492 if test $HAVE_FAAD = yes; then
 493         afh_objs="$afh_objs aac_afh mp4"
 494         audio_format_handlers="$audio_format_handlers aac"
 495 fi
 496 AC_SUBST(afh_objs, add_dot_o($afh_objs))
 497 ########################################################################## play
 498 play_objs="
 499         play
 500         fd
 501         sched
 502         buffer_tree
 503         time
 504         string
 505         net
 506         afh_recv
 507         afh_common
 508         wma_afh
 509         wma_common
 510         mp3_afh
 511         recv_common
 512         udp_recv
 513         http_recv
 514         dccp_recv
 515         filter_common
 516         fec
 517         bitstream
 518         imdct
 519         wav_filter
 520         compress_filter
 521         amp_filter
 522         prebuffer_filter
 523         fecdec_filter
 524         wmadec_filter
 525         write_common
 526         file_write
 527         version
 528         sync_filter
 529         lsu
 530 "
 531 AS_IF([test $NEED_OGG_OBJECTS = yes], [play_objs="$play_objs ogg_afh_common"])
 532 AS_IF([test $NEED_VORBIS_OBJECTS = yes],
 533         [play_objs="$play_objs oggdec_filter ogg_afh"])
 534 AS_IF([test $NEED_SPEEX_OBJECTS = yes],
 535         [play_objs="$play_objs spxdec_filter spx_afh spx_common"])
 536 AS_IF([test $NEED_OPUS_OBJECTS = yes],
 537         [play_objs="$play_objs opusdec_filter opus_afh opus_common"])
 538 AS_IF([test $NEED_FLAC_OBJECTS = yes],
 539         [play_objs="$play_objs flacdec_filter flac_afh"])
 540 if test $HAVE_FAAD = yes; then
 541         play_objs="$play_objs aac_afh aacdec_filter mp4"
 542 fi
 543 if test $HAVE_MAD = yes; then
 544         play_objs="$play_objs mp3dec_filter"
 545 fi
 546 if test $HAVE_OSS = yes; then
 547         play_objs="$play_objs oss_write"
 548 fi
 549 if test $HAVE_ALSA = yes; then
 550         play_objs="$play_objs alsa_write"
 551 fi
 552 if test $NEED_AO_OBJECTS = yes; then
 553         play_objs="$play_objs ao_write"
 554 fi
 555 if test $HAVE_READLINE = yes; then
 556         play_objs="$play_objs interactive"
 557 fi
 558 if test $HAVE_SAMPLERATE = yes; then
 559         play_objs="$play_objs resample_filter check_wav"
 560 fi
 561 AC_SUBST(play_objs, add_dot_o($play_objs))
 562 ######################################################################### write
 563 write_objs="
 564         write
 565         write_common
 566         file_write
 567         time
 568         fd
 569         string
 570         sched
 571         stdin
 572         buffer_tree
 573         check_wav
 574         version
 575 "
 576
 577 if test $NEED_AO_OBJECTS = yes; then
 578         write_objs="$write_objs ao_write"
 579 fi
 580 if test $HAVE_OSS = yes; then
 581         write_objs="$write_objs oss_write"
 582 fi
 583 if test $HAVE_ALSA = yes; then
 584         write_objs="$write_objs alsa_write"
 585 fi
 586 AC_SUBST(write_objs, add_dot_o($write_objs))
 587 ######################################################################## audioc
 588 audioc_objs="
 589         audioc
 590         string
 591         lsu
 592         net
 593         fd
 594         time
 595         version
 596 "
 597 if test $HAVE_READLINE = yes; then
 598         audioc_objs="$audioc_objs
 599                 buffer_tree
 600                 interactive
 601                 sched
 602         "
 603 fi
 604 AC_SUBST(audioc_objs, add_dot_o($audioc_objs))
 605
 606 AC_DEFINE_UNQUOTED(AUDIO_FORMAT_HANDLERS, "$audio_format_handlers",
 607         [formats supported by para_server and para_afh])
 608 AC_SUBST(executables)
 609
 610 AC_OUTPUT
 611 AC_MSG_NOTICE([
 612 paraslash configuration:
 613 ~~~~~~~~~~~~~~~~~~~~~~~~
 614 crypto lib: ${CRYPTOLIB:-[none]}
 615 readline (interactive CLIs): $HAVE_READLINE
 616 id3 version 2 support: $HAVE_ID3TAG
 617 faad: $HAVE_FAAD
 618 audio format handlers: $audio_format_handlers
 619
 620 exe: $executables
 621 para_server: $build_server
 622 para_gui: $build_gui
 623 para_mixer: $build_mixer
 624 para_client: $build_client
 625 para_audiod: $build_audiod
 626 ])