build: ldflags conversion: libvorbis.
[paraslash.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 AC_PREREQ([2.61])
5
6 AC_INIT([paraslash],[git],[maan@systemlinux.org])
7 AC_CONFIG_HEADER([config.h])
8
9 AC_CONFIG_FILES([Makefile])
10 AC_DEFUN([add_dot_o],[$(for i in $@; do printf "$i.o "; done)])
11 AC_DEFUN([add_cmdline],[$(for i in $@; do printf "${i}.cmdline "; done)])
12 AC_DEFUN([objlist_to_errlist],[$(for i in $@; do printf "DEFINE_ERRLIST($(echo $i| tr 'a-z' 'A-Z'));"; done) [const char **para_errlist[[]]] = {$(for i in $@; do printf "PARA_ERRLIST($(echo $i | tr 'a-z' 'A-Z')), "; done) }])
13 AC_PATH_PROG(UNAMEPATH, uname, no)
14 if test "$UNAMEPATH" = "no"; then
15 AC_MSG_ERROR(unable to determine system type)
16 fi
17 AC_MSG_CHECKING(os type)
18 OSTYPE="`$UNAMEPATH -s`"
19 AC_MSG_RESULT("$OSTYPE")
20
21 if test "$OSTYPE" = "SunOS"; then
22 # needed on SunOS for socket magic
23 arch_cppflags="-D_XOPEN_SOURCE=500 -D__EXTENSIONS__"
24 AC_SUBST(arch_cppflags)
25 fi
26
27 AC_C_BIGENDIAN()
28
29 AC_PATH_PROG([gengetopt], [gengetopt])
30 test -z "$gengetopt" && AC_MSG_ERROR(
31 [gengetopt is required to build this package])
32
33 AC_PATH_PROG([help2man], [help2man])
34 test -z "$help2man" && AC_MSG_ERROR(
35 [help2man is required to build this package])
36
37 AC_PATH_PROG([install], [install])
38 test -z "$install" && AC_MSG_ERROR(
39 [The install program is required to build this package])
40
41 AC_PROG_CC
42 AC_PROG_CPP
43
44 AC_HEADER_DIRENT
45 AC_HEADER_STDC
46 AC_HEADER_SYS_WAIT
47 AC_HEADER_STDBOOL
48 AC_CHECK_HEADERS([arpa/inet.h ctype.h fcntl.h limits.h netdb.h netinet/in.h \
49 stdlib.h string.h sys/socket.h sys/time.h sys/timeb.h sys/un.h \
50 sys/ipc.h unistd.h utime.h stddef.h],
51 [], [AC_MSG_ERROR([$ac_header not found])])
52
53 # Checks for typedefs, structures, and compiler characteristics.
54 AC_C_CONST
55 AC_C_INLINE
56 AC_TYPE_OFF_T
57 AC_TYPE_PID_T
58 AC_TYPE_SIZE_T
59 AC_HEADER_TIME
60 AC_STRUCT_TM
61 AC_TYPE_INT8_T
62 AC_TYPE_INT16_T
63 AC_TYPE_INT32_T
64 AC_TYPE_INT64_T
65 AC_TYPE_MODE_T
66 AC_TYPE_SSIZE_T
67 AC_TYPE_UID_T
68 AC_TYPE_UINT8_T
69 AC_TYPE_UINT16_T
70 AC_TYPE_UINT32_T
71 AC_TYPE_UINT64_T
72
73 # Checks for library functions.
74 AC_FUNC_FORK
75 AC_PROG_GCC_TRADITIONAL
76 AC_FUNC_MEMCMP
77 AC_FUNC_MKTIME
78 AC_FUNC_MMAP
79 AC_FUNC_SELECT_ARGTYPES
80 AC_FUNC_STAT
81 AC_FUNC_STRFTIME
82 AC_FUNC_VPRINTF
83 AC_FUNC_CLOSEDIR_VOID
84 AC_FUNC_LSTAT
85
86 AC_CHECK_FUNCS([atexit dup2 memchr memmove memset \
87 regcomp select strchr strdup strerror strstr strtol uname \
88 fchdir gettimeofday localtime_r munmap strcasecmp strcspn \
89 strncasecmp strrchr strspn alarm mkdir inet_ntoa socket], [],
90 [AC_MSG_ERROR([function not found, cannot live without it])])
91
92 executables="recv filter audioc write afh play"
93 audio_format_handlers="mp3 wma"
94
95 recv_cmdline_objs="
96 recv
97 http_recv
98 dccp_recv
99 udp_recv
100 afh_recv
101 "
102
103 recv_errlist_objs="
104 http_recv
105 recv_common
106 recv
107 time
108 string
109 net
110 dccp_recv
111 fd
112 sched
113 stdout
114 ggo
115 udp_recv
116 buffer_tree
117 afh_recv
118 afh_common
119 wma_afh
120 wma_common
121 mp3_afh
122 version
123 "
124
125 recv_ldflags=""
126
127 filter_cmdline_objs="
128 filter
129 compress_filter
130 amp_filter
131 prebuffer_filter
132 "
133 filter_errlist_objs="
134 filter_common
135 wav_filter
136 compress_filter
137 filter
138 string
139 stdin
140 stdout
141 sched
142 fd
143 amp_filter
144 ggo
145 fecdec_filter
146 fec
147 version
148 prebuffer_filter
149 time
150 bitstream
151 imdct
152 wma_common
153 wmadec_filter
154 buffer_tree
155 "
156 filter_ldflags="-lm"
157 filters="
158 compress
159 wav
160 amp
161 fecdec
162 wmadec
163 prebuffer
164 "
165
166 audioc_cmdline_objs="audioc"
167 audioc_errlist_objs="
168 audioc
169 string
170 net
171 fd
172 version
173 ggo
174 "
175 audioc_ldflags=""
176
177 afh_cmdline_objs="afh"
178 afh_errlist_objs="
179 afh
180 string
181 fd
182 mp3_afh
183 afh_common
184 time
185 wma_afh
186 wma_common
187 version
188 ggo
189 "
190 afh_ldflags=""
191
192 write_cmdline_objs="
193 write
194 file_write
195 "
196 write_errlist_objs="
197 write
198 write_common
199 file_write
200 time
201 fd
202 string
203 sched
204 stdin
205 buffer_tree
206 ggo
207 check_wav
208 version
209 "
210 write_ldflags=""
211 writers="file"
212 default_writer="FILE_WRITE"
213
214 play_errlist_objs="
215 play
216 fd
217 sched
218 ggo
219 buffer_tree
220 time
221 string
222 net
223 afh_recv
224 afh_common
225 wma_afh
226 wma_common
227 mp3_afh
228 recv_common
229 udp_recv
230 http_recv
231 dccp_recv
232 filter_common
233 fec
234 bitstream
235 imdct
236 wav_filter
237 compress_filter
238 amp_filter
239 prebuffer_filter
240 fecdec_filter
241 wmadec_filter
242 write_common
243 file_write
244 version
245 "
246 play_cmdline_objs="
247 http_recv
248 dccp_recv
249 udp_recv
250 afh_recv
251 compress_filter
252 amp_filter
253 prebuffer_filter
254 file_write
255 play
256 "
257 play_ldflags="-lm"
258 ################################################################## clock_gettime
259 clock_gettime_lib=
260 AC_CHECK_LIB([c], [clock_gettime], [clock_gettime_lib=c], [
261 AC_CHECK_LIB([rt], [clock_gettime], [clock_gettime_lib=rt], [], [])
262 ])
263 if test -n "$clock_gettime_lib"; then
264 AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [
265 define to 1 if clock_gettime() is supported])
266 fi
267 if test "$clock_gettime_lib" = "rt"; then
268 AC_SUBST(clock_gettime_ldflags, -lrt)
269 fi
270 ########################################################################### osl
271 have_osl=yes
272 OLD_CPPFLAGS="$CPPFLAGS"
273 OLD_LDFLAGS="$LDFLAGS"
274 OLD_LIBS="$LIBS"
275 AC_ARG_WITH(osl_headers, [AS_HELP_STRING(--with-osl-headers=dir,
276 [look for osl.h also in dir])])
277 if test -n "$with_osl_headers"; then
278 osl_cppflags="-I$with_osl_headers"
279 CPPFLAGS="$CPPFLAGS $osl_cppflags"
280 fi
281 AC_ARG_WITH(osl_libs, [AS_HELP_STRING(--with-osl-libs=dir,
282 [look for libosl also in dir])])
283 if test -n "$with_osl_libs"; then
284 osl_libs="-L$with_osl_libs"
285 LDFLAGS="$LDFLAGS $osl_libs"
286 fi
287
288 AC_CHECK_HEADER(osl.h, [], have_osl=no)
289 AC_CHECK_LIB([osl], [osl_open_table], [], have_osl=no)
290 if test "$have_osl" = "no"; then
291 AC_MSG_WARN([libosl not found, can not build para_server.
292 Download libosl at
293 http://systemlinux.org/~maan/osl
294 or execute
295 git clone git://git.tuebingen.mpg.de/osl
296 ])
297 fi
298 AC_SUBST(osl_cppflags)
299 CPPFLAGS="$OLD_CPPFLAGS"
300 LDFLAGS="$OLD_LDFLAGS"
301 LIBS="$OLD_LIBS"
302 ########################################################################### crypto
303 AC_ARG_ENABLE(cryptolib, [AS_HELP_STRING(--enable-cryptolib=lib, [
304 Force using crypto library "lib". This package requires either
305 openssl or libgcrypt being installed. Possible values for "lib"
306 are thus "openssl" and "gcrypt". If this option is not given,
307 openssl is tried first. If openssl was not found, gcrypt is
308 tried next.])])
309
310 case "$enable_cryptolib" in
311 "openssl") check_openssl="yes"; check_gcrypt="no";;
312 "gcrypt") check_openssl="no"; check_gcrypt="yes";;
313 "") check_openssl="yes"; check_gcrypt="yes";;
314 *) AC_MSG_ERROR([invalid value "$enable_cryptolib" for --enable-cryptolib]);;
315 esac
316 ###################################################################### openssl
317 if test "$check_openssl" = "yes"; then
318 OLD_CPPFLAGS="$CPPFLAGS"
319 OLD_LDFLAGS="$LDFLAGS"
320 OLD_LIBS="$LIBS"
321 have_openssl="yes"
322 AC_ARG_WITH(openssl_headers, [AS_HELP_STRING(--with-openssl-headers=dir,
323 [look for openssl headers also in dir])])
324 if test -n "$with_openssl_headers"; then
325 openssl_cppflags="-I$with_openssl_headers"
326 CPPFLAGS="$CPPFLAGS $openssl_cppflags"
327 fi
328 AC_ARG_WITH(openssl_libs, [AS_HELP_STRING(--with-openssl-libs=dir,
329 [look for openssl libraries also in dir])])
330 if test -n "$with_openssl_libs"; then
331 openssl_libs="-L$with_openssl_libs"
332 LDFLAGS="$LDFLAGS $openssl_libs"
333 fi
334 AC_CHECK_HEADER(openssl/ssl.h, [], [have_openssl="no"])
335 AC_CHECK_LIB([crypto], [RAND_bytes], [], [have_openssl="no"])
336 if test "$have_openssl" = "no" -a -z "$with_openssl_headers$with_openssl_libs"; then
337 # try harder: openssl is sometimes installed in /usr/local/ssl
338 openssl_cppflags="-I/usr/local/ssl/include"
339 CPPFLAGS="$CPPFLAGS $openssl_cppflags"
340 openssl_libs="-L/usr/local/ssl/lib"
341 LDFLAGS="$LDFLAGS $openssl_libs"
342 # clear cache
343 unset ac_cv_header_openssl_ssl_h 2> /dev/null
344 unset ac_cv_lib_crypto_RAND_bytes 2> /dev/null
345 AC_CHECK_HEADER(openssl/ssl.h, [have_openssl="yes"], [])
346 if test "$have_openssl" = "yes"; then
347 AC_CHECK_LIB([crypto], [RAND_bytes], [], [have_openssl="no"])
348 fi
349 fi
350 if test "$have_openssl" = "yes"; then
351 AC_DEFINE(HAVE_OPENSSL, 1, [define to 1 to turn on openssl support])
352 AC_SUBST(openssl_cppflags)
353 openssl_libs="$openssl_libs -lssl -lcrypto"
354 server_ldflags="$server_ldflags $openssl_libs"
355 client_ldflags="$client_ldflags $openssl_libs"
356 audiod_ldflags="$audiod_ldflags $openssl_libs"
357
358 server_errlist_objs="$server_errlist_objs crypt"
359 client_errlist_objs="$client_errlist_objs crypt"
360 audiod_errlist_objs="$audiod_errlist_objs crypt"
361
362 check_gcrypt="no"
363 else
364 AC_MSG_WARN([openssl libraries not found])
365 fi
366 CPPFLAGS="$OLD_CPPFLAGS"
367 LDFLAGS="$OLD_LDFLAGS"
368 LIBS="$OLD_LIBS"
369 else
370 have_openssl="no"
371 fi
372 ########################################################################### gcrypt
373 if test "$check_gcrypt" = "yes"; then
374 OLD_CPPFLAGS="$CPPFLAGS"
375 OLD_LDFLAGS="$LDFLAGS"
376 OLD_LIBS="$LIBS"
377 have_gcrypt="yes"
378 AC_ARG_WITH(gcrypt_headers, [AS_HELP_STRING(--with-gcrypt-headers=dir,
379 [look for gcrypt headers also in dir])])
380 if test -n "$with_gcrypt_headers"; then
381 gcrypt_cppflags="-I$with_gcrypt_headers"
382 CPPFLAGS="$CPPFLAGS $gcrypt_cppflags"
383 fi
384 AC_ARG_WITH(gcrypt_libs, [AS_HELP_STRING(--with-gcrypt-libs=dir,
385 [look for libgcrypt also in dir])])
386 if test -n "$with_gcrypt_libs"; then
387 gcrypt_libs="-L$with_gcrypt_libs"
388 LDFLAGS="$LDFLAGS $gcrypt_libs"
389 fi
390 AC_CHECK_HEADER(gcrypt.h, [], [have_gcrypt="no"])
391 AC_CHECK_LIB([gcrypt], [gcry_randomize], [], [have_gcrypt="no"])
392 if test "$have_gcrypt" = "yes"; then
393 AC_DEFINE(HAVE_GCRYPT, 1, [define to 1 to turn on gcrypt support])
394 AC_SUBST(gcrypt_cppflags)
395 gcrypt_libs="$gcrypt_libs -lgcrypt"
396 server_ldflags="$server_ldflags $gcrypt_libs"
397 client_ldflags="$client_ldflags $gcrypt_libs"
398 audiod_ldflags="$audiod_ldflags $gcrypt_libs"
399
400 server_errlist_objs="$server_errlist_objs gcrypt"
401 client_errlist_objs="$client_errlist_objs gcrypt"
402 audiod_errlist_objs="$audiod_errlist_objs gcrypt"
403 else
404 AC_MSG_WARN([gcrypt library not found])
405 fi
406 CPPFLAGS="$OLD_CPPFLAGS"
407 LDFLAGS="$OLD_LDFLAGS"
408 LIBS="$OLD_LIBS"
409 else
410 have_gcrypt="no"
411 fi
412 ########################################################################### libsocket
413 AC_CHECK_LIB([c], [socket],
414 [socket_lib=],
415 [socket_lib="-lsocket"]
416 )
417 server_ldflags="$server_ldflags $socket_lib"
418 client_ldflags="$client_ldflags $socket_lib"
419 audioc_ldflags="$audioc_ldflags $socket_lib"
420 audiod_ldflags="$audiod_ldflags $socket_lib"
421 recv_ldflags="$recv_ldflags $socket_lib"
422 AC_SEARCH_LIBS([connect],[socket],[],[
423 AC_MSG_ERROR([Fatal: Did not find connect().])
424 ],[])
425 ########################################################################### libnsl
426 AC_CHECK_LIB([c], [gethostbyname],
427 [nsl_lib=],
428 [nsl_lib="-lnsl"]
429 )
430 server_ldflags="$server_ldflags $nsl_lib"
431 client_ldflags="$client_ldflags $nsl_lib"
432 audioc_ldflags="$audioc_ldflags $nsl_lib"
433 recv_ldflags="$recv_ldflags $nsl_lib"
434 AC_SEARCH_LIBS([inet_ntoa],[nsl],[],[
435 AC_MSG_ERROR([Fatal: Did not find inet_ntoa().])
436 ],[])
437 ########################################################################### ucred
438 AC_MSG_CHECKING(for struct ucred)
439 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
440 #define _GNU_SOURCE
441 #include <sys/types.h>
442 #include <sys/socket.h>
443 ]], [[
444 struct ucred sucred; sucred.pid=0;
445 ]])],[have_ucred=yes],[have_ucred=no])
446 AC_MSG_RESULT($have_ucred)
447 if test ${have_ucred} = yes; then
448 AC_DEFINE(HAVE_UCRED, 1, define to 1 you have struct ucred)
449 fi
450 ########################################################################### gengetopt
451 echo 'option "z" z "" flag off' | $gengetopt --file-name conftest-ggo &&
452 AC_CHECK_DECL(
453 [gengetopt_args_info_description],
454 [ggo_descriptions_declared=yes],
455 [ggo_descriptions_declared=no],
456 [#include "conftest-ggo.h"]
457 )
458 AC_SUBST(ggo_descriptions_declared)
459 ########################################################################### curses
460 have_curses="yes"
461 OLD_CPPFLAGS="$CPPFLAGS"
462 OLD_LDFLAGS="$LDFLAGS"
463 OLD_LIBS="$LIBS"
464 AC_ARG_WITH(curses_headers, [AS_HELP_STRING(--with-curses-headers=dir,
465 [look for curses.h also in dir])])
466 if test -n "$with_curses_headers"; then
467 curses_cppflags="-I$with_curses_headers"
468 CPPFLAGS="$CPPFLAGS $curses_cppflags"
469 fi
470 AC_ARG_WITH(curses_libs, [AS_HELP_STRING(--with-curses-libs=dir,
471 [look for libcurses also in dir])])
472 if test -n "$with_curses_libs"; then
473 curses_libs="-L$with_curses_libs"
474 LDFLAGS="$LDFLAGS $curses_libs"
475 fi
476 AC_CHECK_HEADER(curses.h, [], [
477 have_curses="no"
478 ])
479 curses_ldflags="$curses_libs"
480 AC_CHECK_LIB([ncursesw], [initscr],
481 [curses_ldflags="$curses_libs -lncursesw"], [
482 AC_CHECK_LIB([curses], [initscr],
483 [curses_ldflags="$curses_libs -lcurses"],
484 [have_curses="no"]
485 )
486 ]
487 )
488 AC_SUBST(curses_cppflags)
489 AC_SUBST(curses_ldflags)
490 CPPFLAGS="$OLD_CPPFLAGS"
491 LDFLAGS="$OLD_LDFLAGS"
492 LIBS="$OLD_LIBS"
493 ########################################################################### ip_mreqn
494 AC_MSG_CHECKING(for struct ip_mreqn (UDPv4 multicast))
495 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
496 #include <netdb.h>
497 #include <net/if.h>
498 ]], [[
499 struct ip_mreqn mn;
500 mn.imr_ifindex = 0;
501 ]])],[have_ip_mreqn=yes],[have_ip_mreqn=no])
502 AC_MSG_RESULT($have_ip_mreqn)
503 if test ${have_ip_mreqn} = yes; then
504 AC_DEFINE(HAVE_IP_MREQN, 1, define to 1 you have struct ip_mreqn)
505 fi
506 ########################################################################### osx
507
508 AC_MSG_CHECKING(for CoreAudio (MacOs))
509 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
510 #include <CoreAudio/CoreAudio.h>
511 ]], [[
512 AudioDeviceID id;
513 ]])],[have_core_audio=yes],[have_core_audio=no])
514 AC_MSG_RESULT($have_core_audio)
515 if test ${have_core_audio} = yes; then
516 f1="-framework CoreAudio"
517 f2="-framework AudioToolbox"
518 f3="-framework AudioUnit"
519 f4="-framework CoreServices"
520 f="$f1 $f2 $f3 $f4"
521
522 audiod_errlist_objs="$audiod_errlist_objs osx_write ipc"
523 audiod_cmdline_objs="$audiod_cmdline_objs osx_write.cmdline"
524 audiod_ldflags="$audiod_ldflags $f"
525
526 play_errlist_objs="$play_errlist_objs osx_write ipc"
527 play_cmdline_objs="$play_cmdline_objs osx_write.cmdline"
528 play_ldflags="$play_ldflags $f"
529
530 write_errlist_objs="$write_errlist_objs osx_write ipc"
531 write_cmdline_objs="$write_cmdline_objs osx_write.cmdline"
532 write_ldflags="$write_ldflags $f"
533 writers="$writers osx"
534 default_writer="OSX_WRITE"
535 AC_DEFINE(HAVE_CORE_AUDIO, 1, define to 1 on Mac Os X)
536 fi
537 ####################################################### ogg/vorbis/speex/opus
538 have_ogg="yes"
539 OLD_CPPFLAGS="$CPPFLAGS"
540 OLD_LDFLAGS="$LDFLAGS"
541 OLD_LIBS="$LIBS"
542 AC_ARG_WITH(ogg_headers, [AS_HELP_STRING(--with-ogg-headers=dir,
543 [look for ogg headers also in dir])])
544 AC_ARG_WITH(ogg_libs, [AS_HELP_STRING(--with-ogg-libs=dir,
545 [look for ogg libs also in dir])])
546 AC_ARG_WITH(vorbis_headers, [AS_HELP_STRING(--with-vorbis-headers=dir,
547 [look for vorbis headers also in dir])])
548 AC_ARG_WITH(vorbis_libs, [AS_HELP_STRING(--with-vorbis-libs=dir,
549 [look for vorbis libs also in dir])])
550 AC_ARG_WITH(speex_headers, [AS_HELP_STRING(--with-speex-headers=dir,
551 [look for speex headers also in dir])])
552 AC_ARG_WITH(speex_libs, [AS_HELP_STRING(--with-speex-libs=dir,
553 [look for speex libs also in dir])])
554 AC_ARG_WITH(opus_headers, [AS_HELP_STRING(--with-opus-headers=dir,
555 [look for opus headers also in dir])])
556 AC_ARG_WITH(opus_libs, [AS_HELP_STRING(--with-opus-libs=dir,
557 [look for opus libs also in dir])])
558
559 if test -n "$with_ogg_headers"; then
560 ogg_cppflags="-I$with_ogg_headers"
561 CPPFLAGS="$CPPFLAGS $ogg_cppflags"
562 fi
563 if test -n "$with_ogg_libs"; then
564 ogg_libs="-L$with_ogg_libs"
565 LDFLAGS="$LDFLAGS $ogg_libs"
566 fi
567 AC_CHECK_HEADERS([ogg/ogg.h], [], [ have_ogg="no"; ])
568 AC_CHECK_LIB([ogg], [ogg_stream_init], [], [ have_ogg="no" ])
569
570 have_vorbis="yes"
571 have_speex="yes"
572 have_opus="yes"
573 if test "$have_ogg" = "yes"; then
574 # vorbis
575 if test -n "$with_vorbis_headers"; then
576 vorbis_cppflags="-I$with_vorbis_headers"
577 CPPFLAGS="$CPPFLAGS $vorbis_cppflags"
578 fi
579 if test -n "$with_vorbis_libs"; then
580 vorbis_libs="-L$with_vorbis_libs"
581 LDFLAGS="$LDFLAGS $vorbis_libs"
582 fi
583 AC_CHECK_HEADERS([vorbis/codec.h], [], [ have_vorbis="no" ])
584 AC_CHECK_LIB([vorbis], [vorbis_info_init], [], [ have_vorbis="no" ])
585
586 # speex
587 if test -n "$with_speex_headers"; then
588 speex_cppflags="-I$with_speex_headers"
589 CPPFLAGS="$CPPFLAGS $speex_cppflags"
590 fi
591 if test -n "$with_speex_libs"; then
592 speex_libs="-L$with_speex_libs"
593 LDFLAGS="$LDFLAGS $speex_libs"
594 fi
595 AC_CHECK_LIB([speex], [speex_decoder_init], [], [ have_speex="no" ])
596 AC_CHECK_HEADERS([speex/speex.h], [], [ have_speex="no" ])
597
598 # opus
599 if test -n "$with_opus_headers"; then
600 opus_cppflags="-I$with_opus_headers"
601 CPPFLAGS="$CPPFLAGS $opus_cppflags"
602 fi
603 if test -n "$with_opus_libs"; then
604 opus_libs="-L$with_opus_libs"
605 LDFLAGS="$LDFLAGS $opus_libs"
606 fi
607 AC_CHECK_LIB([opus], [opus_multistream_decode], [], [ have_opus="no" ])
608 AC_CHECK_HEADERS([opus/opus.h], [], [ have_opus="no" ])
609 else
610 AC_MSG_WARN([vorbis/speex/opus depend on libogg, which was not detected])
611 have_vorbis="no"
612 have_speex="no"
613 have_opus="no"
614 fi
615
616 msg="support in para_server/para_filter/para_afh"
617 if test "$have_vorbis" = "yes" || \
618 test "$have_speex" = "yes" || \
619 test "$have_opus" = "yes"; then
620 AC_SUBST(ogg_cppflags)
621 ogg_ldflags="$ogg_libs -logg"
622 if test "$OSTYPE" = "Darwin"; then
623 ogg_ldflags="-Wl,-bind_at_load $ogg_ldflags"
624 fi
625 AC_SUBST(ogg_ldflags)
626 afh_errlist_objs="$afh_errlist_objs ogg_afh_common"
627 recv_errlist_objs="$recv_errlist_objs ogg_afh_common"
628 server_errlist_objs="$server_errlist_objs ogg_afh_common"
629 play_errlist_objs="$play_errlist_objs ogg_afh_common"
630 fi
631 if test "$have_vorbis" = "yes"; then
632 AC_DEFINE(HAVE_OGGVORBIS, 1, define to 1 to turn on ogg/vorbis support)
633 filters="$filters oggdec"
634 vorbis_ldflags="$vorbis_libs -lvorbis -lvorbisfile"
635 AC_SUBST(vorbis_ldflags)
636
637 server_errlist_objs="$server_errlist_objs ogg_afh"
638 filter_errlist_objs="$filter_errlist_objs oggdec_filter"
639 audiod_errlist_objs="$audiod_errlist_objs oggdec_filter"
640 play_errlist_objs="$play_errlist_objs oggdec_filter ogg_afh"
641 afh_errlist_objs="$afh_errlist_objs ogg_afh"
642 recv_errlist_objs="$recv_errlist_objs ogg_afh"
643
644 audiod_audio_formats="$audiod_audio_formats ogg"
645 audio_format_handlers="$audio_format_handlers ogg"
646 fi
647 if test "$have_speex" = "yes"; then
648 AC_DEFINE(HAVE_SPEEX, 1, define to 1 to turn on ogg/speex support)
649 filters="$filters spxdec"
650 speex_libs="-lspeex"
651 server_ldflags="$server_ldflags $speex_libs"
652 filter_ldflags="$filter_ldflags $speex_libs"
653 audiod_ldflags="$audiod_ldflags $speex_libs"
654 play_ldflags="$play_ldflags $speex_libs"
655 afh_ldflags="$afh_ldflags $speex_libs"
656 recv_ldflags="$recv_ldflags $speex_libs"
657
658 server_errlist_objs="$server_errlist_objs spx_afh spx_common"
659 filter_errlist_objs="$filter_errlist_objs spxdec_filter spx_common"
660 audiod_errlist_objs="$audiod_errlist_objs spxdec_filter spx_common"
661 play_errlist_objs="$play_errlist_objs spxdec_filter spx_afh spx_common"
662 afh_errlist_objs="$afh_errlist_objs spx_afh spx_common"
663 recv_errlist_objs="$recv_errlist_objs spx_afh spx_common"
664
665 audiod_audio_formats="$audiod_audio_formats spx"
666 audio_format_handlers="$audio_format_handlers spx"
667 else
668 AC_MSG_WARN([no ogg/speex $msg])
669 fi
670 if test "$have_opus" = "yes"; then
671 AC_DEFINE(HAVE_OPUS, 1, define to 1 to turn on ogg/opus support)
672 filters="$filters opusdec"
673 opus_libs="-lopus"
674 server_ldflags="$server_ldflags $opus_libs"
675 filter_ldflags="$filter_ldflags $opus_libs"
676 audiod_ldflags="$audiod_ldflags $opus_libs"
677 afh_ldflags="$afh_ldflags $opus_libs"
678 play_ldflags="$play_ldflags $opus_libs"
679 recv_ldflags="$recv_ldflags $opus_libs"
680
681 server_errlist_objs="$server_errlist_objs opus_afh opus_common"
682 filter_errlist_objs="$filter_errlist_objs opusdec_filter opus_common"
683 audiod_errlist_objs="$audiod_errlist_objs opusdec_filter opus_common"
684 afh_errlist_objs="$afh_errlist_objs opus_afh opus_common"
685 play_errlist_objs="$play_errlist_objs opusdec_filter opus_afh opus_common"
686 recv_errlist_objs="$recv_errlist_objs opus_afh opus_common"
687
688 audiod_audio_formats="$audiod_audio_formats opus"
689 audio_format_handlers="$audio_format_handlers opus"
690 else
691 AC_MSG_WARN([no ogg/opus $msg])
692 fi
693 CPPFLAGS="$OLD_CPPFLAGS"
694 LDFLAGS="$OLD_LDFLAGS"
695 LIBS="$OLD_LIBS"
696 ########################################################################### faad
697 have_faad=yes
698 OLD_CPPFLAGS="$CPPFLAGS"
699 OLD_LDFLAGS="$LDFLAGS"
700 OLD_LIBS="$LIBS"
701 AC_ARG_WITH(faad_headers, [AS_HELP_STRING(--with-faad-headers=dir,
702 [look for neaacdec.h also in dir])])
703 if test -n "$with_faad_headers"; then
704 faad_cppflags="-I$with_faad_headers"
705 CPPFLAGS="$CPPFLAGS $faad_cppflags"
706 fi
707 AC_ARG_WITH(faad_libs, [AS_HELP_STRING(--with-faad-libs=dir,
708 [look for libfaad also in dir])])
709 if test -n "$with_faad_libs"; then
710 faad_libs="-L$with_faad_libs"
711 LDFLAGS="$LDFLAGS $faad_libs"
712 fi
713 AC_CHECK_HEADER(neaacdec.h, [], have_faad=no)
714 AC_CHECK_LIB([faad], [NeAACDecOpen], [], have_faad=no)
715 if test "$have_faad" = "yes"; then
716 AC_DEFINE(HAVE_FAAD, 1, define to 1 if you want to build the aacdec filter)
717 filter_errlist_objs="$filter_errlist_objs aacdec_filter aac_common"
718 afh_errlist_objs="$afh_errlist_objs aac_common aac_afh"
719 audiod_errlist_objs="$audiod_errlist_objs aacdec_filter aac_common"
720 play_errlist_objs="$play_errlist_objs aacdec_filter aac_afh aac_common"
721 server_errlist_objs="$server_errlist_objs aac_afh aac_common"
722 recv_errlist_objs="$recv_errlist_objs aac_afh aac_common"
723
724 server_ldflags="$server_ldflags $faad_libs -lfaad"
725 filter_ldflags="$filter_ldflags $faad_libs -lfaad"
726 audiod_ldflags="$audiod_ldflags $faad_libs -lfaad"
727 play_ldflags="$play_ldflags $faad_libs -lfaad"
728 afh_ldflags="$afh_ldflags $faad_libs -lfaad"
729 recv_ldflags="$afh_ldflags $faad_libs -lfaad"
730
731 audiod_audio_formats="$audiod_audio_formats aac"
732 audio_format_handlers="$audio_format_handlers aac"
733 filters="$filters aacdec"
734 AC_SUBST(faad_cppflags)
735 else
736 AC_MSG_WARN([no aac support in para_audiod/para_filter])
737 fi
738 CPPFLAGS="$OLD_CPPFLAGS"
739 LDFLAGS="$OLD_LDFLAGS"
740 LIBS="$OLD_LIBS"
741 ########################################################################### mad
742 have_mad="yes"
743 OLD_CPPFLAGS="$CPPFLAGS"
744 OLD_LDFLAGS="$LDFLAGS"
745 OLD_LIBS="$LIBS"
746
747 AC_ARG_WITH(mad_headers, [AS_HELP_STRING(--with-mad-headers=dir,
748 [look for mad.h also in dir])])
749 if test -n "$with_mad_headers"; then
750 mad_cppflags="-I$with_mad_headers"
751 CPPFLAGS="$CPPFLAGS $mad_cppflags"
752 fi
753 AC_ARG_WITH(mad_libs, [AS_HELP_STRING(--with-mad-libs=dir,
754 [look for libmad also in dir])])
755 if test -n "$with_mad_libs"; then
756 mad_libs="-L$with_mad_libs"
757 LDFLAGS="$LDFLAGS $mad_libs"
758 fi
759 AC_CHECK_HEADERS([mad.h], [], [
760 have_mad="no"
761 ])
762 AC_CHECK_LIB([mad], [mad_stream_init], [], [
763 have_mad="no"
764 ])
765 if test "$have_mad" = "yes"; then
766 AC_DEFINE(HAVE_MAD, 1, define to 1 if you want to build the mp3dec filter)
767 filter_cmdline_objs="$filter_cmdline_objs mp3dec_filter"
768 audiod_cmdline_objs="$audiod_cmdline_objs mp3dec_filter"
769 play_cmdline_objs="$play_cmdline_objs mp3dec_filter"
770 filter_errlist_objs="$filter_errlist_objs mp3dec_filter"
771 audiod_errlist_objs="$audiod_errlist_objs mp3dec_filter"
772 play_errlist_objs="$play_errlist_objs mp3dec_filter"
773 filter_ldflags="$filter_ldflags $mad_libs -lmad"
774 audiod_ldflags="$audiod_ldflags $mad_libs -lmad"
775 play_ldflags="$play_ldflags $mad_libs -lmad"
776 audiod_audio_formats="$audiod_audio_formats mp3"
777 filters="$filters mp3dec"
778 AC_SUBST(mad_cppflags)
779 else
780 AC_MSG_WARN([no mp3dec support in para_audiod/para_filter])
781 fi
782 CPPFLAGS="$OLD_CPPFLAGS"
783 LDFLAGS="$OLD_LDFLAGS"
784 LIBS="$OLD_LIBS"
785 ###################################################################### libid3tag
786 OLD_CPPFLAGS="$CPPFLAGS"
787 OLD_LDFLAGS="$LDFLAGS"
788 OLD_LIBS="$LIBS"
789
790 have_libid3tag="yes"
791 AC_ARG_WITH(id3tag_headers, [AS_HELP_STRING(--with-id3tag-headers=dir,
792 [look for id3tag header files also in dir])])
793 if test -n "$with_id3tag_headers"; then
794 id3tag_cppflags="-I$with_id3tag_headers"
795 CPPFLAGS="$CPPFLAGS $id3tag_cppflags"
796 fi
797 AC_ARG_WITH(id3tag_libs, [AS_HELP_STRING(--with-id3tag-libs=dir,
798 [look for id3tag libs also in dir])])
799 if test -n "$with_id3tag_libs"; then
800 id3tag_libs="-L$with_id3tag_libs"
801 LDFLAGS="$LDFLAGS $id3tag_libs"
802 fi
803
804 AC_MSG_CHECKING(for libid3tag)
805 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
806 #include <id3tag.h>
807 ]], [[
808 struct id3_tag t = {.flags = 0};
809 ]])],[],[have_libid3tag=no])
810 AC_MSG_RESULT($have_libid3tag)
811
812 if test ${have_libid3tag} = yes; then
813 AC_DEFINE(HAVE_LIBID3TAG, 1, define to 1 you have libid3tag)
814 AC_SUBST(id3tag_cppflags)
815 AC_SUBST(id3tag_ldflags, "$id3tag_libs -lid3tag -lz")
816 fi
817 CPPFLAGS="$OLD_CPPFLAGS"
818 LDFLAGS="$OLD_LDFLAGS"
819 LIBS="$OLD_LIBS"
820 ########################################################################### flac
821 OLD_CPPFLAGS="$CPPFLAGS"
822 OLD_LDFLAGS="$LDFLAGS"
823 OLD_LIBS="$LIBS"
824
825 have_flac="yes"
826 AC_ARG_WITH(flac_headers, [AS_HELP_STRING(--with-flac-headers=dir,
827 [look for flac headers also in dir])])
828 if test -n "$with_flac_headers"; then
829 flac_cppflags="-I$with_flac_headers"
830 CPPFLAGS="$CPPFLAGS $flac_cppflags"
831 fi
832 AC_ARG_WITH(flac_libs, [AS_HELP_STRING(--with-flac-libs=dir,
833 [look for flac libs also in dir])])
834 if test -n "$with_flac_libs"; then
835 flac_libs="-L$with_flac_libs"
836 LDFLAGS="$LDFLAGS $flac_libs"
837 fi
838 AC_CHECK_HEADER(FLAC/stream_decoder.h, [], have_flac=no)
839 AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_init_file], [], have_flac=no, -logg -lm)
840 if test "$have_flac" = "yes"; then
841 AC_DEFINE(HAVE_FLAC, 1, define to 1 if you want to build the flacdec filter)
842 filter_errlist_objs="$filter_errlist_objs flacdec_filter"
843 audiod_errlist_objs="$audiod_errlist_objs flacdec_filter"
844 play_errlist_objs="$play_errlist_objs flacdec_filter flac_afh"
845 afh_errlist_objs="$afh_errlist_objs flac_afh"
846 server_errlist_objs="$server_errlist_objs flac_afh"
847 recv_errlist_objs="$recv_errlist_objs flac_afh"
848 filter_ldflags="$filter_ldflags $flac_libs -lFLAC"
849 audiod_ldflags="$audiod_ldflags $flac_libs -lFLAC"
850 play_ldflags="$play_ldflags $flac_libs -lFLAC"
851 server_ldflags="$server_ldflags $flac_libs -lFLAC"
852 afh_ldflags="$afh_ldflags $flac_libs -lFLAC"
853 recv_ldflags="$recv_ldflags $flac_libs -lFLAC"
854 filters="$filters flacdec"
855 audio_format_handlers="$audio_format_handlers flac"
856 audiod_audio_formats="$audiod_audio_formats flac"
857 AC_SUBST(flac_cppflags)
858 else
859 AC_MSG_WARN([no flac support in para_audiod/para_filter/para_afh/para_server])
860 fi
861 CPPFLAGS="$OLD_CPPFLAGS"
862 LDFLAGS="$OLD_LDFLAGS"
863 LIBS="$OLD_LIBS"
864 ########################################################################### oss
865 OLD_CPPFLAGS="$CPPFLAGS"
866 OLD_LDFLAGS="$LDFLAGS"
867 OLD_LIBS="$LIBS"
868
869 have_oss="yes"
870 msg="=> will not build oss writer"
871
872 AC_CHECK_HEADER(sys/soundcard.h, [
873 audiod_errlist_objs="$audiod_errlist_objs oss_write"
874 play_errlist_objs="$play_errlist_objs oss_write"
875 audiod_cmdline_objs="$audiod_cmdline_objs oss_write"
876 play_cmdline_objs="$play_cmdline_objs oss_write"
877
878 write_errlist_objs="$write_errlist_objs oss_write"
879 write_cmdline_objs="$write_cmdline_objs oss_write"
880 fade_errlist_objs="$fade_errlist_objs oss_mix"
881
882 writers="$writers oss"
883 default_writer="OSS_WRITE"
884 mixers="${mixers}oss "
885 default_mixer="OSS_MIX"
886
887 AC_CHECK_LIB(ossaudio, _oss_ioctl, [
888 audiod_ldflags="$audiod_ldflags -lossaudio"
889 play_ldflags="$play_ldflags -lossaudio"
890 write_ldflags="$write_ldflags -lossaudio"
891 fade_ldflags="$fade_ldflags -lossaudio"
892 ]
893 )
894 ],
895 [
896 have_oss="no"
897 AC_MSG_WARN([no sys/soundcard.h $msg])
898 ]
899 )
900 CPPFLAGS="$OLD_CPPFLAGS"
901 LDFLAGS="$OLD_LDFLAGS"
902 LIBS="$OLD_LIBS"
903
904 ########################################################################### alsa
905 OLD_CPPFLAGS="$CPPFLAGS"
906 OLD_LDFLAGS="$LDFLAGS"
907 OLD_LIBS="$LIBS"
908
909 msg="=> no alsa support for para_audiod/para_write"
910 if test "$OSTYPE" != "Linux"; then
911 have_alsa="no"
912 else
913 have_alsa="yes"
914 fi
915 if test "$have_alsa" = "yes"; then
916 AC_CHECK_HEADERS([alsa/asoundlib.h], [], [
917 have_alsa="no"
918 AC_MSG_WARN([no alsa/asoundlib $msg])
919 ])
920 fi
921
922 if test "$have_alsa" = "yes"; then
923 AC_CHECK_LIB([asound], [snd_pcm_open], [], [
924 have_alsa="no"
925 AC_MSG_WARN([no libasound $msg])
926 ])
927 fi
928
929 if test "$have_alsa" = "yes"; then
930 audiod_errlist_objs="$audiod_errlist_objs alsa_write"
931 audiod_cmdline_objs="$audiod_cmdline_objs alsa_write"
932 audiod_ldflags="$audiod_ldflags -lasound"
933 play_errlist_objs="$play_errlist_objs alsa_write"
934 play_cmdline_objs="$play_cmdline_objs alsa_write"
935 play_ldflags="$play_ldflags -lasound"
936
937 write_errlist_objs="$write_errlist_objs alsa_write"
938 write_cmdline_objs="$write_cmdline_objs alsa_write"
939 write_ldflags="$write_ldflags -lasound"
940 fade_errlist_objs="$fade_errlist_objs alsa_mix"
941 fade_ldflags="$fade_ldflags -lasound"
942
943 writers="$writers alsa"
944 default_writer="ALSA_WRITE"
945 mixers="${mixers}alsa "
946 default_mixer="ALSA_MIX"
947 fi
948
949 CPPFLAGS="$OLD_CPPFLAGS"
950 LDFLAGS="$OLD_LDFLAGS"
951 LIBS="$OLD_LIBS"
952 ########################################################################### libao
953 OLD_CPPFLAGS="$CPPFLAGS"
954 OLD_LDFLAGS="$LDFLAGS"
955 OLD_LIBS="$LIBS"
956
957 have_ao="yes"
958 AC_ARG_WITH(ao_headers, [AS_HELP_STRING(--with-ao-headers=dir,
959 [look for ao/ao.h also in dir])])
960 if test -n "$with_ao_headers"; then
961 ao_cppflags="-I$with_ao_headers"
962 CPPFLAGS="$CPPFLAGS $ao_cppflags"
963 fi
964 AC_ARG_WITH(ao_libs, [AS_HELP_STRING(--with-ao-libs=dir,
965 [look for libao also in dir])])
966 if test -n "$with_ao_libs"; then
967 ao_libs="-L$with_ao_libs"
968 LDFLAGS="$LDFLAGS $ao_libs"
969 fi
970 msg="no libao support for para_audiod/para_write"
971 AC_CHECK_HEADERS([ao/ao.h], [
972 ], [
973 have_ao="no"
974 AC_MSG_WARN([ao.h not found, $msg])
975 ])
976 if test "$have_ao" = "yes"; then
977 AC_CHECK_LIB([ao], [ao_initialize], [], [
978 have_ao="no"
979 AC_MSG_WARN([ao lib not found or not working, $msg])
980 ])
981 fi
982 if test "$have_ao" = "yes"; then
983 AC_CHECK_HEADERS([pthread.h], [
984 ], [
985 have_ao="no"
986 AC_MSG_WARN([pthread.h not found, $msg])
987 ])
988 fi
989 if test "$have_ao" = "yes"; then
990 AC_CHECK_LIB([pthread], [pthread_create], [], [
991 have_ao="no"
992 AC_MSG_WARN([pthread lib not found or not working, $msg])
993 ])
994 fi
995 if test "$have_ao" = "yes"; then
996 audiod_errlist_objs="$audiod_errlist_objs ao_write"
997 audiod_cmdline_objs="$audiod_cmdline_objs ao_write"
998 audiod_ldflags="$audiod_ldflags -lao -lpthread"
999
1000 play_errlist_objs="$play_errlist_objs ao_write"
1001 play_cmdline_objs="$play_cmdline_objs ao_write"
1002 play_ldflags="$play_ldflags -lao -lpthread"
1003
1004 write_errlist_objs="$write_errlist_objs ao_write"
1005 write_cmdline_objs="$write_cmdline_objs ao_write"
1006 write_ldflags="$write_ldflags $ao_libs -lao -lpthread"
1007 writers="$writers ao"
1008 AC_SUBST(ao_cppflags)
1009 fi
1010
1011 CPPFLAGS="$OLD_CPPFLAGS"
1012 LDFLAGS="$OLD_LDFLAGS"
1013 LIBS="$OLD_LIBS"
1014 ############################################################# readline
1015 OLD_CPPFLAGS="$CPPFLAGS"
1016 OLD_LDFLAGS="$LDFLAGS"
1017 OLD_LIBS="$LIBS"
1018
1019 have_readline="yes"
1020 AC_ARG_WITH(readline_headers, [AS_HELP_STRING(--with-readline-headers=dir,
1021 [look for libreadline header files also in dir])])
1022 if test -n "$with_readline_headers"; then
1023 readline_cppflags="-I$with_readline_headers"
1024 CPPFLAGS="$CPPFLAGS $readline_cppflags"
1025 fi
1026
1027 AC_ARG_WITH(readline_libs, [AS_HELP_STRING(--with-readline-libs=dir,
1028 [look for readline library also in dir])])
1029 if test -n "$with_readline_libs"; then
1030 readline_libs="-L$with_readline_libs"
1031 LDFLAGS="$LDFLAGS $readline_libs"
1032 fi
1033 msg="no interactive cli support"
1034 AC_CHECK_HEADERS([readline/readline.h], [
1035 ], [
1036 have_readline="no"
1037 AC_MSG_WARN([readline/readline.h not found, $msg])
1038 ])
1039
1040 if test "$have_curses" != "yes"; then
1041 have_readline="no"
1042 AC_MSG_WARN([interactive cli support depends on curses,])
1043 AC_MSG_WARN([but no curses lib was detected, $msg])
1044 fi
1045
1046 if test "$have_readline" = "yes"; then
1047 readline_libs="$readline_libs -lreadline"
1048 AC_SEARCH_LIBS([rl_free_keymap], [readline], [], [have_readline="no"])
1049 if test "$have_readline" = "no"; then # try with -lcurses
1050 # clear cache
1051 AC_MSG_NOTICE([trying again with -lcurses])
1052 unset ac_cv_search_rl_free_keymap 2> /dev/null
1053 AC_SEARCH_LIBS([rl_free_keymap], [readline], [
1054 have_readline=yes
1055 readline_libs="$readline_libs -lcurses"
1056 ], [], [-lcurses])
1057 fi
1058 if test "$have_readline" = "no"; then # try with -ltermcap
1059 # clear cache
1060 AC_MSG_NOTICE([trying again with -ltermcap])
1061 unset ac_cv_search_rl_free_keymap 2> /dev/null
1062 AC_SEARCH_LIBS([rl_free_keymap], [readline], [
1063 have_readline=yes
1064 readline_libs="$readline_libs -ltermcap"
1065 ], [], [-ltermcap])
1066 fi
1067 fi
1068
1069 if test "$have_readline" = "yes"; then
1070 client_errlist_objs="$client_errlist_objs interactive"
1071 client_ldflags="$client_ldflags $readline_libs"
1072 audioc_errlist_objs="$audioc_errlist_objs buffer_tree interactive sched time"
1073 audioc_ldflags="$audioc_ldflags $readline_libs"
1074 play_errlist_objs="$play_errlist_objs interactive"
1075 play_ldflags="$play_ldflags $readline_libs"
1076 AC_SUBST(readline_cppflags)
1077 AC_DEFINE(HAVE_READLINE, 1, define to 1 to turn on readline support)
1078 else
1079 AC_MSG_WARN([libreadline not found or unusable])
1080 fi
1081 CPPFLAGS="$OLD_CPPFLAGS"
1082 LDFLAGS="$OLD_LDFLAGS"
1083 LIBS="$OLD_LIBS"
1084 ############################################################# libsamplerate
1085 OLD_CPPFLAGS="$CPPFLAGS"
1086 OLD_LDFLAGS="$LDFLAGS"
1087 OLD_LIBS="$LIBS"
1088
1089 have_samplerate="yes"
1090 AC_ARG_WITH(samplerate_headers, [AS_HELP_STRING(--with-samplerate-headers=dir,
1091 [look for samplerate headers also in dir])])
1092 if test -n "$with_samplerate_headers"; then
1093 samplerate_cppflags="-I$with_samplerate_headers"
1094 CPPFLAGS="$CPPFLAGS $samplerate_cppflags"
1095 fi
1096 AC_ARG_WITH(samplerate_libs, [AS_HELP_STRING(--with-samplerate-libs=dir,
1097 [look for samplerate libs also in dir])])
1098 if test -n "$with_samplerate_libs"; then
1099 samplerate_libs="-L$with_samplerate_libs"
1100 LDFLAGS="$LDFLAGS $samplerate_libs"
1101 fi
1102
1103 AC_CHECK_HEADER(samplerate.h, [], have_samplerate=no)
1104 AC_CHECK_LIB([samplerate], [src_process], [], have_samplerate=no, [])
1105
1106 if test "$have_samplerate" = "yes"; then
1107 filter_errlist_objs="$filter_errlist_objs resample_filter check_wav"
1108 filter_cmdline_objs="$filter_cmdline_objs resample_filter"
1109 audiod_errlist_objs="$audiod_errlist_objs resample_filter check_wav"
1110 audiod_cmdline_objs="$audiod_cmdline_objs resample_filter"
1111 play_errlist_objs="$play_errlist_objs resample_filter check_wav"
1112 play_cmdline_objs="$play_cmdline_objs resample_filter"
1113 filter_ldflags="$filter_ldflags $samplerate_libs -lsamplerate"
1114 audiod_ldflags="$audiod_ldflags $samplerate_libs -lsamplerate"
1115 play_ldflags="$play_ldflags $samplerate_libs -lsamplerate"
1116 filters="$filters resample"
1117 AC_SUBST(samplerate_cppflags)
1118 else
1119 AC_MSG_WARN([no resample support in para_audiod/para_filter])
1120 fi
1121 CPPFLAGS="$OLD_CPPFLAGS"
1122 LDFLAGS="$OLD_LDFLAGS"
1123 LIBS="$OLD_LIBS"
1124 ######################################################################### server
1125 if test \( "$have_openssl" = "yes" -o "$have_gcrypt" = "yes" \) \
1126 -a "$have_osl" = "yes" ; then
1127
1128 build_server="yes"
1129 executables="$executables server"
1130 server_cmdline_objs="server"
1131 server_errlist_objs="$server_errlist_objs
1132 server
1133 afh_common
1134 mp3_afh
1135 vss
1136 command
1137 net
1138 string
1139 signal
1140 time
1141 daemon
1142 http_send
1143 close_on_fork
1144 mm
1145 crypt_common
1146 ipc
1147 dccp_send
1148 fd
1149 user_list
1150 chunk_queue
1151 afs
1152 aft
1153 mood
1154 score
1155 attribute
1156 blob
1157 playlist
1158 sched
1159 acl
1160 send_common
1161 udp_send
1162 color
1163 fec
1164 wma_afh
1165 wma_common
1166 sideband
1167 version
1168 ggo
1169 "
1170 server_ldflags="$server_ldflags $osl_libs -losl"
1171 else
1172 build_server="no"
1173 fi
1174 ############################################################# client
1175 if test "$have_openssl" = "yes" -o "$have_gcrypt" = "yes"; then
1176 build_client="yes"
1177 executables="$executables client"
1178 client_cmdline_objs="client"
1179 client_errlist_objs="$client_errlist_objs
1180 client
1181 net
1182 string
1183 fd
1184 sched
1185 stdin
1186 stdout
1187 time
1188 sideband
1189 client_common
1190 buffer_tree
1191 crypt_common
1192 version
1193 ggo
1194 "
1195 else
1196 build_client="no"
1197 fi
1198 ############################################################# audiod
1199 if test "$have_openssl" = "yes" -o "$have_gcrypt" = "yes"; then
1200 build_audiod="yes"
1201 executables="$executables audiod"
1202 audiod_cmdline_objs="$audiod_cmdline_objs
1203 audiod
1204 compress_filter
1205 http_recv
1206 dccp_recv
1207 file_write
1208 client
1209 amp_filter
1210 udp_recv
1211 prebuffer_filter
1212 "
1213 audiod_errlist_objs="$audiod_errlist_objs
1214 audiod
1215 signal
1216 string
1217 daemon
1218 stat
1219 net
1220 crypt_common
1221 sideband
1222 time
1223 grab_client
1224 filter_common
1225 wav_filter
1226 compress_filter
1227 amp_filter
1228 http_recv
1229 dccp_recv
1230 recv_common
1231 fd
1232 sched
1233 write_common
1234 file_write
1235 audiod_command
1236 fecdec_filter
1237 client_common
1238 ggo
1239 udp_recv
1240 color
1241 fec
1242 prebuffer_filter
1243 version
1244 bitstream
1245 imdct
1246 wma_common
1247 wmadec_filter
1248 buffer_tree
1249 "
1250 audiod_ldflags="$audiod_ldflags -lm"
1251 audiod_audio_formats="$audiod_audio_formats wma"
1252 else
1253 build_audiod="no"
1254 fi
1255 ########################################################################### fade
1256 if test -n "$mixers"; then
1257 build_fade="yes"
1258 executables="$executables fade"
1259 fade_errlist_objs="$fade_errlist_objs fade exec string fd version ggo"
1260 fade_cmdline_objs="fade"
1261 fade_objs="add_cmdline($fade_cmdline_objs) $fade_errlist_objs"
1262 AC_SUBST(fade_objs, add_dot_o($fade_objs))
1263 AC_SUBST(fade_ldflags, $fade_ldflags)
1264 AC_DEFINE_UNQUOTED(INIT_FADE_ERRLISTS,
1265 objlist_to_errlist($fade_errlist_objs),
1266 errors used by para_fade)
1267 enum="$(
1268 for i in $mixers; do
1269 printf "${i}_MIX, " | tr '[a-z]' '[A-Z]'
1270 done
1271 )"
1272 AC_DEFINE_UNQUOTED(MIXER_ENUM, $enum NUM_SUPPORTED_MIXERS,
1273 enum of supported mixers)
1274 AC_DEFINE_UNQUOTED(DEFAULT_MIXER, $default_mixer,
1275 use this mixer if none was specified)
1276 names="$(for i in $mixers; do printf \"$i\",' ' ; done)"
1277 AC_DEFINE_UNQUOTED(MIXER_NAMES, $names, supported mixer names)
1278 inits="$(
1279 for i in $mixers; do
1280 printf 'extern void '$i'_mix_init(struct mixer *); '
1281 done
1282 )"
1283 AC_DEFINE_UNQUOTED(DECLARE_MIXER_INITS, $inits,
1284 init functions of the supported mixers)
1285 array="$(for i in $mixers; do printf '{.init = '$i'_mix_init},'; done)"
1286 AC_DEFINE_UNQUOTED(MIXER_ARRAY, $array, array of supported mixers)
1287 mixer_summary="supported mixers:: $mixers, default: $default_mixer"
1288 else
1289 build_fade="no"
1290 AC_MSG_WARN([no mixer support])
1291 mixer_summary="para_fade: no"
1292 fi
1293 ########################################################################### gui
1294 if test "$have_curses" = "yes"; then
1295 build_gui="yes"
1296 executables="$executables gui"
1297 gui_cmdline_objs="gui"
1298 gui_errlist_objs="
1299 exec
1300 signal
1301 string
1302 stat
1303 ringbuffer
1304 fd
1305 gui
1306 gui_theme
1307 time
1308 version
1309 ggo
1310 "
1311 gui_objs="add_cmdline($gui_cmdline_objs) $gui_errlist_objs"
1312 else
1313 build_gui="no"
1314 AC_MSG_WARN([no curses lib, cannot build para_gui])
1315 fi
1316 ############################################################# error2.h
1317 # these are always built
1318 all_errlist_objs="
1319 $recv_errlist_objs
1320 $filter_errlist_objs
1321 $audioc_errlist_objs
1322 $write_errlist_objs
1323 $afh_errlist_objs
1324 $play_errlist_objs
1325 "
1326
1327 # optional executables
1328 if test "$build_server" = "yes"; then
1329 all_errlist_objs="$all_errlist_objs $server_errlist_objs"
1330 fi
1331 if test "$build_gui" = "yes"; then
1332 all_errlist_objs="$all_errlist_objs $gui_errlist_objs"
1333 fi
1334 if test "$build_fade" = "yes"; then
1335 all_errlist_objs="$all_errlist_objs $fade_errlist_objs"
1336 fi
1337 if test "$build_client" = "yes"; then
1338 all_errlist_objs="$all_errlist_objs $client_errlist_objs"
1339 fi
1340 if test "$build_audiod" = "yes"; then
1341 all_errlist_objs="$all_errlist_objs $audiod_errlist_objs"
1342 fi
1343
1344 all_errlist_objs="$(echo $all_errlist_objs | tr ' ' '\n' | sort | uniq)"
1345
1346 object_executable_matrix=
1347 for i in $executables; do
1348 eval objs=\$${i}_errlist_objs
1349 object_executable_matrix="$object_executable_matrix $i: $objs"
1350 done
1351 # use echo to replace newlines by space
1352 AC_SUBST(object_executable_matrix, $(echo $object_executable_matrix))
1353
1354 for obj in $all_errlist_objs; do
1355 SS="$SS SS_$(echo $obj | tr 'a-z' 'A-Z'),"
1356 done
1357 AC_DEFINE_UNQUOTED(DEFINE_ERRLIST_OBJECT_ENUM,
1358 [enum {$SS NUM_SS}],
1359 [list of all objects that use the paraslash error facility]
1360 )
1361 ################################################################## status items
1362
1363 status_items="basename status num_played mtime bitrate frequency file_size
1364 status_flags format score techinfo afs_mode
1365 attributes_txt decoder_flags audiod_status play_time attributes_bitmap
1366 offset seconds_total stream_start current_time audiod_uptime image_id
1367 lyrics_id duration directory lyrics_name image_name path hash channels
1368 last_played num_chunks chunk_time amplification artist title year album
1369 comment"
1370
1371 result=
1372 for i in $status_items; do
1373 result="$result SI_$(echo $i | tr 'a-z' 'A-Z'), "
1374 done
1375 AC_DEFINE_UNQUOTED(STATUS_ITEM_ENUM, [$result],
1376 [enum of all status items])
1377
1378 result=
1379 for i in $status_items; do
1380 result="$result \"$i\", "
1381 done
1382 AC_DEFINE_UNQUOTED(STATUS_ITEM_ARRAY, [$result],
1383 [char * array of all status items])
1384
1385 AC_DEFINE_UNQUOTED(AUDIO_FORMAT_HANDLERS, "$audio_format_handlers",
1386 [formats supported by para_server and para_afh])
1387
1388 AC_SUBST(executables)
1389
1390 recv_objs="add_cmdline($recv_cmdline_objs) $recv_errlist_objs"
1391 filter_objs="add_cmdline($filter_cmdline_objs) $filter_errlist_objs"
1392 audiod_objs="add_cmdline($audiod_cmdline_objs) $audiod_errlist_objs"
1393 server_objs="add_cmdline($server_cmdline_objs) $server_errlist_objs"
1394 write_objs="add_cmdline($write_cmdline_objs) $write_errlist_objs"
1395 client_objs="add_cmdline($client_cmdline_objs) $client_errlist_objs"
1396 audioc_objs="add_cmdline($audioc_cmdline_objs) $audioc_errlist_objs"
1397 afh_objs="add_cmdline($afh_cmdline_objs) $afh_errlist_objs"
1398 play_objs="add_cmdline($play_cmdline_objs) $play_errlist_objs"
1399 gui_objs="add_cmdline($gui_cmdline_objs) $gui_errlist_objs"
1400
1401 AC_SUBST(recv_objs, add_dot_o($recv_objs))
1402 AC_SUBST(recv_ldflags, $recv_ldflags)
1403 AC_DEFINE_UNQUOTED(INIT_RECV_ERRLISTS, objlist_to_errlist($recv_errlist_objs),
1404 errors used by para_recv)
1405
1406 AC_SUBST(filter_objs, add_dot_o($filter_objs))
1407 AC_SUBST(filter_ldflags, $filter_ldflags)
1408 AC_DEFINE_UNQUOTED(INIT_FILTER_ERRLISTS,
1409 objlist_to_errlist($filter_errlist_objs), errors used by para_filter)
1410
1411 AC_SUBST(audiod_objs, add_dot_o($audiod_objs))
1412 AC_SUBST(audiod_ldflags, $audiod_ldflags)
1413 AC_DEFINE_UNQUOTED(INIT_AUDIOD_ERRLISTS, objlist_to_errlist($audiod_errlist_objs),
1414 errors used by para_audiod)
1415
1416 AC_SUBST(server_objs, add_dot_o($server_objs))
1417 AC_SUBST(server_ldflags, $server_ldflags)
1418 AC_DEFINE_UNQUOTED(INIT_SERVER_ERRLISTS,
1419 objlist_to_errlist($server_errlist_objs), errors used by para_server)
1420
1421 AC_SUBST(afh_objs, add_dot_o($afh_objs))
1422 AC_SUBST(afh_ldflags, $afh_ldflags)
1423 AC_DEFINE_UNQUOTED(INIT_AFH_ERRLISTS,
1424 objlist_to_errlist($afh_errlist_objs), errors used by para_afh)
1425
1426 AC_SUBST(write_objs, add_dot_o($write_objs))
1427 AC_SUBST(write_ldflags, $write_ldflags)
1428 AC_DEFINE_UNQUOTED(INIT_WRITE_ERRLISTS,
1429 objlist_to_errlist($write_errlist_objs), errors used by para_write)
1430
1431 AC_SUBST(client_objs, add_dot_o($client_objs))
1432 AC_SUBST(client_ldflags, $client_ldflags)
1433 AC_DEFINE_UNQUOTED(INIT_CLIENT_ERRLISTS,
1434 objlist_to_errlist($client_errlist_objs), errors used by para_client)
1435
1436 AC_SUBST(audioc_objs, add_dot_o($audioc_objs))
1437 AC_SUBST(audioc_ldflags, $audioc_ldflags)
1438 AC_DEFINE_UNQUOTED(INIT_AUDIOC_ERRLISTS,
1439 objlist_to_errlist($audioc_errlist_objs), errors used by para_audioc)
1440
1441 AC_SUBST(gui_objs, add_dot_o($gui_objs))
1442 AC_DEFINE_UNQUOTED(INIT_GUI_ERRLISTS,
1443 objlist_to_errlist($gui_errlist_objs), errors used by para_gui)
1444
1445 AC_SUBST(play_objs, add_dot_o($play_objs))
1446 AC_SUBST(play_ldflags, $play_ldflags)
1447 AC_DEFINE_UNQUOTED(INIT_PLAY_ERRLISTS,
1448 objlist_to_errlist($play_errlist_objs), errors used by para_play)
1449
1450 enum="$(for i in $filters; do printf "${i}_FILTER, " | tr '[a-z]' '[A-Z]'; done)"
1451 AC_DEFINE_UNQUOTED(FILTER_ENUM, $enum NUM_SUPPORTED_FILTERS,
1452 enum of supported filters)
1453 inits="$(for i in $filters; do printf 'extern void '$i'_filter_init(struct filter *f); '; done)"
1454 AC_DEFINE_UNQUOTED(DECLARE_FILTER_INITS, $inits, init functions of the supported filters)
1455 array="$(for i in $filters; do printf '{.name = "'$i'", .init = '$i'_filter_init},'; done)"
1456 AC_DEFINE_UNQUOTED(FILTER_ARRAY, $array, array of supported filters)
1457
1458 enum="$(for i in $writers; do printf "${i}_WRITE, " | tr '[a-z]' '[A-Z]'; done)"
1459 AC_DEFINE_UNQUOTED(WRITER_ENUM, $enum NUM_SUPPORTED_WRITERS,
1460 enum of supported writers)
1461 AC_DEFINE_UNQUOTED(DEFAULT_WRITER, $default_writer, use this writer if none was specified)
1462 names="$(for i in $writers; do printf \"$i\",' ' ; done)"
1463 AC_DEFINE_UNQUOTED(WRITER_NAMES, $names, supported writer names)
1464 inits="$(for i in $writers; do printf 'extern void '$i'_write_init(struct writer *); '; done)"
1465 AC_DEFINE_UNQUOTED(DECLARE_WRITER_INITS, $inits, init functions of the supported writers)
1466 array="$(for i in $writers; do printf '{.init = '$i'_write_init},'; done)"
1467 AC_DEFINE_UNQUOTED(WRITER_ARRAY, $array, array of supported writers)
1468
1469 enum="$(for i in $audiod_audio_formats; do printf "AUDIO_FORMAT_${i}, " | tr '[a-z]' '[A-Z]'; done)"
1470 AC_DEFINE_UNQUOTED(AUDIOD_AUDIO_FORMATS_ENUM, $enum NUM_AUDIO_FORMATS,
1471 enum of audio formats supported by audiod)
1472 names="$(for i in $audiod_audio_formats; do printf \"$i\",' ' ; done)"
1473 AC_DEFINE_UNQUOTED(AUDIOD_AUDIO_FORMAT_ARRAY, $names, array of audio formats supported by audiod)
1474
1475 AC_OUTPUT
1476 AC_MSG_NOTICE([
1477 paraslash configuration:
1478 ~~~~~~~~~~~~~~~~~~~~~~~~
1479 unix socket credentials: $have_ucred
1480 readline (interactive CLIs): $have_readline
1481 audio formats handlers: $audio_format_handlers
1482 id3 version2 support: $have_libid3tag
1483 filters: $(echo $filters)
1484 writers: $writers
1485
1486 $mixer_summary
1487 para_server: $build_server
1488 para_gui: $build_gui
1489 para_fade: $build_fade
1490 para_client: $build_client
1491 para_audiod: $build_audiod
1492 ])